Erm, so just do it. You've said what you want, write the code.

my %hits;
while( <> ) {
  my( $key ) = /HIT:\s+(\S+)/;
  $hits{ $key }++;
}
my @distinct = keys %hits;
[download]

Now you didn't say so, but if you want to preserve the order things appear in the input just push onto a list and use the hash to tell what you've already seen.

my @hits;
my %seen;
while( <> ) {
  my( $key ) = /HIT:\s+(\S+)/;
  next if $seen{ $key }++;
  push @hits, $key;
}
[download]

#!/usr/bin/perl -w
use strict;
use Data::Dumper::Simple;

my %codes;

while (<DATA>) {
    chomp;
    my $foo = (split /:/, $_)[1];
    if (!$codes{$foo}) {
        $codes{$foo}++;
    }
}

print Dumper(%codes);

__DATA__
HIT: code2
HIT: code3
HIT: code1
HIT: code90
HIT: code2
HIT: code34
HIT: code90
[download]

Which prints:

%codes = (
           ' code90' => 1,
           ' code2' => 1,
           ' code3' => 1,
           ' code2 ' => 1,
           ' code1' => 1,
           ' code34' => 1
         );
[download]

Actually, you don't really need the "if" block inside the while loop. You could just increment each hash value regardless. That won't give you any duplicates - it will just mean that some have a higher numerical value. Which (if I understand correctly) shouldn't make any difference.

Hope this helps,
Darren :)

Minor nit, but if you amend the split slightly to my $foo = (split /:\s+/, $_)[1];you can eliminate the leading space from the hash keys. That space might trip you up later if you are expecting to be able to do something like if ( exists $codes{q{code90}} ) { ... }.

Cheers,

JohnGG

...
while(<DATA>){
        /:\s(\S+)$/ => $1
           and $code{$1}++
}
...
[download]

Looks like a slightly bigger question there than has been answered so far. Consider this:

use warnings;
use strict;

my %codeData;
my $skipping = 0;
my $currCode;

while (<DATA>) {
    if (/^HIT: (\S+)/) {
        $currCode = $1;
        $skipping = exists $codeData{$currCode};
        next;
    }
    
    next if $skipping;
    $codeData{$currCode} .= $_;
}

print $codeData{$_} for keys %codeData;

__DATA__
HIT: code2
stuff for code2
HIT: code3
stuff for code3
HIT: code1
stuff for code1
HIT: code90
stuff for code90
HIT: code2
extra stuff for code2 - ignore this
HIT: code34
stuff for code34
HIT: code90
and extra stuff for code90 - ignore this
[download]

Prints:

stuff for code90
stuff for code3
stuff for code2
stuff for code34
stuff for code1
[download]

Note in particular the use of exists to see if there is an element in the hash already. That frees you to store interesting stuff there rather than an explicit "found it" flag.