open(OUTPUTFILE, '>$position_output_path')

Variables aren't expanded in single-quoted strings. You're opening a file called $position_output_path. You need double quotes.

while (<OUTPUTFILE>) { print OUTPUTFILE @rows;}

While you can read from OUTPUTFILE (which is opened for writing only - so you aren't going to get any data back anyway) write a record to the filehandle. That's not right. You probably just need:

print OUTPUTFILE @rows;
[download]

You're confusing reading of files with writing to files. Use the diamond operator (<OUTPUTFILE>) to read from a file. When you're writing to a file, there's no need to use the diamond operator, and in fact it won't work to use it.

Here's how to do it:

open( OUTPUTFILE, '>', $position_output_path )
    or die "Couldn't open $position_output_path\n$!";
foreach my $row ( @rows ) {
    print OUTPUTFILE $row, "\n";
}
close( OUTPUTFILE )
    or die "Couldn't close $position_output_path\n$!";
[download]

That ought to do the trick!

Thanks, folks! *slaps head*

Greetings back O seeker of wisdom.

Your basic problem is the while loop. Remove it and see what happens:

 open(OUTPUTFILE, '>$position_output_path') 
  or die "Could not open $position_output_path:$!\n";
 print OUTPUTFILE @rows;            
 close(OUTPUTFILE) 
  or die "Could not close $position_output_path:$!
[download]

 open(OUTPUTFILE, ">$position_output_path") 
  or die "Could not open $position_output_path:$!\n";
 print OUTPUTFILE @rows;            
 close(OUTPUTFILE) 
  or die "Could not close $position_output_path:$!
[download]

Update: Need double quotes as davorg points out below.

That still opens and writes to a file called "$position_output_path" - and I doubt that's what the original poster wants :-)

--
<http://dave.org.uk>

"The first rule of Perl club is you do not talk about Perl club."
-- Chip Salzenberg

for (@rows) {
    print OUTPUTFILE "$_\n";
}
[download]

Cheers,
Darren :)

Another couple of tips:

1/ it is generally considered good practice to use the three parameter open:

open (OUTPUTFILE, '>', $position_output_path) or die "Could not open .
+..";
[download]

2/ print @array prints the stringified contents of an array without any additional whitespace. print "@array" prints the stringified contents of an array with $, added between each item.

Note also that join can be used to inster whatever seperators you like between elements of an array.

Consider:

my $var;
my @array = ('a', 1.1, \$var);

print @array;
print "\n@array";
print "\n", join "\n", @array;
[download]

Prints:

a1.1SCALAR(0x182f68c)
a 1.1 SCALAR(0x182f68c)
a
1.1
SCALAR(0x182f68c)
[download]

use Tie::File;
tie my @file, 'Tie::File', $position_output_path;
@file = @rows;
untie @file;
[download]