use Data::Dumper;
my @asdf = (qw/A B C D E F/);
my %hash;
my $hr = \%hash;
for(@asdf) { 
    $hr->{$_} = { };
    $hr = $hr->{$_};
}

print Dumper \%hash;
[download]

That prints:

$VAR1 = {
          'A' => {
                   'B' => {
                            'C' => {
                                     'D' => {
                                              'E' => {
                                                       'F' => {}
                                                     }
                                            }
                                   }
                          }
                 }
        };
[download]

my $hash;
$hash = { $_ => $hash } for reverse @array;
[download]

my $ref = \$hash;
$ref = \$$ref->{$_} for @b;
[download]

I want some clarification. Are you trying to create a hash with the keys of "A, B, C, D, E, and F", or are you trying to create a multi-dimensional datastructure, a hash of hashes of hashes of hashes (and so on)?

Here are a couple examples of "how to do it", depending on what it actually is:

# Create a hash with keys from @asdf
my %hash;
@hash{ @asdf } = (); # Use a hash slice.

# Create a multidimensional datastructure:
my $href;
foreach my $key ( reverse @asdf ) {
    $href = { $key => $href };
}
[download]

The latter approach creates a datastructure referenced by $href. It's built "in reverse" just to simplify the algorithm.

You can use tye's Data::Diver:

use Data::Diver qw( DiveVal );

my %hash;

my @keys = qw( A B C D E F ... );
DiveVal(\%hash, @keys);
[download]

Caveat: It won't work if one of the keys looks like a number.

Tested.

See Recursively walk a hash to get to an element and Autovivification trick

In the same spirit as jdporter's reply, you might have a look at Re: I've got a hash of hashes how do i get my values out. If you have problems (as I still sometimes do) looking at a complex data structure and figuring out "Okay, exactly what do I have here?", you may find How can I visualize my complex data structure? useful.

HTH,