It's a side effect from calling glob in scalar context:

       glob EXPR
       glob    In list context, returns a (possibly empty) list of fil
+ename
               expansions on the value of EXPR such as the standard Un
+ix shell
               /bin/csh would do. In scalar context, glob iterates thr
+ough
               such filename expansions, returning undef when the list
+ is
               exhausted. This is the internal function implementing t
+he
               "<*.c>" operator, but you can use it directly. If EXPR 
+is omit-
               ted, $_ is used.  The "<*.c>" operator is discussed in 
+more
               detail in "I/O Operators" in perlop.
[download]

Try instead:

...
    my ($filename)=glob("$path*$_*.pkl");
    if (defined($filename))
...
[download]

Update: See graff's explanation for more specifics

if(defined (my $filename=(glob("$path*$_*.pkl"))))

Based on those extra parentheses, it looks like you're trying to call glob in list context (which would make more sense, too). But parentheses on the right hand side of assignment do not a list assignment make. Put them on the left hand side instead.

Also, an empty list assignment in scalar context is actually defined (zero, to be precise), so you likely want this:

if(my ($filename)=glob("$path*$_*.pkl"))
[download]

He's checking if a file exists, so a simpler fix would be to use the command designed to check just that: -e (or -f).

#!/usr/bin/perl

use strict;
use warnings;

my $path='C:/dataset/';

my @sign_arr=('A1', 'A2', 'A3','A4', 'A5', 'A6', 'A7', 'A8', 'A9'); 

foreach (@sign_arr)
{
    my $filename = "$path*$_*.pkl";
    if (-e $filename)
    {print "$filename $_\n"}
    else
    {print "not found $_\n";}
}
[download]

Update: Ack, nevermind, I didn't notice his use of *. First post of the morning, sorry.

use File::Find::Rule;

my @wanted = File::Find::Rule->file()
    ->name( qr/A[0-9].*\.pkl$/ )
    ->in('c:/dataset/');
[download]

People typing lines like this:

my @sign_arr=('A1', 'A2', 'A3','A4', 'A5', 'A6', 'A7', 'A8', 'A9');
[download]

make the lazy man in me cringe :)

Using the range operator in list context to produce lists of automagically incremented values was one of the first things I learned to reduce typing... :

my @sign_arr = 'A1'..'A9';
[download]

Hi.

calin++

Just to illustrate what is available...



my @sign_arr = qw(A1 A2 A3 A4 A5 A6 A7 A8 A9);
[download]

 while (glob '*.pkl') {print qq(Found $1 in $_\n) if /(A[1-9])/}
[download]

The explanation was alluded to above, but not actually spelled out in the thread. It lies in the "I/O Operators" section of the perlop man page:

A (file)glob evaluates its (embedded) argument only when it is starting a new list. All values must be read before it will start over. In list context, this isn't important because you automatically get them all anyway. However, in scalar context the operator returns the next value each time it's called, or "undef" when the list has run out. As with filehandle reads, an automatic "defined" is generated when the glob occurs in the test part of a "while", because legal glob returns (e.g. a file called 0) would otherwise terminate the loop. Again, "undef" is returned only once. So if you're expecting a single value from a glob, it is much better to say

           ($file) = <blurch*>;
[download]

than

           $file = <blurch*>;
[download]

because the latter will alternate between returning a filename and returning false.

That's some pretty arcane stuff, but I think it gets the point across, which is: even though you would expect the file glob to "start fresh" each time you use it with a new string, it won't, unless it has already reached the end of a list that it built on a previous call.

As used in the OP (globbed string matches one file, glob is used in a scalar context), it takes two iterations to reach the end of the first list, and thereafter only the odd-numbered glob strings are actually processed.

Hi fellows, i would like to point out the different behavior of glob utilized in scalar context when the key is a variable or a literal.

WRONG

my @sign_arr=('A1' .. 'A9');
for my $sign (@sign_arr) {
     my $filename = <*$sign*.pkl>;
     print "$filename\n" if defined($filename);
}

# OUTPUT:
# file_A1_.pkl
# file_A3_.pkl
# file_A5_.pkl
# file_A7_.pkl
# file_A9_.pkl


# RIGHT

my $filename;
$filename = <*A1*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A2*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A3*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A4*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A5*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A6*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A7*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A8*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A9*.pkl>;
print "$filename\n" if defined($filename);

# OUTPUT:
# file_A1_.pkl
# file_A2_.pkl
# file_A3_.pkl
# file_A4_.pkl
# file_A5_.pkl
# file_A6_.pkl
# file_A7_.pkl
# file_A8_.pkl
# file_A9_.pkl
[download]

A bug?

WRONG

my @sign_arr=('A1' .. 'A9');
for my $sign (@sign_arr) {
     my $filename = <*$sign*.pkl>;
     print "$filename\n" if defined($filename);
}

# OUTPUT:
# file_A1_.pkl
# file_A3_.pkl
# file_A5_.pkl
# file_A7_.pkl
# file_A9_.pkl


# RIGHT

my $filename;
$filename = <*A1*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A2*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A3*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A4*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A5*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A6*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A7*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A8*.pkl>;
print "$filename\n" if defined($filename);
$filename = <*A9*.pkl>;
print "$filename\n" if defined($filename);

# OUTPUT:
# file_A1_.pkl
# file_A2_.pkl
# file_A3_.pkl
# file_A4_.pkl
# file_A5_.pkl
# file_A6_.pkl
# file_A7_.pkl
# file_A8_.pkl
# file_A9_.pkl
[download]