Find unmatched between an array and a hash

hotyopa has asked for the wisdom of the Perl Monks concerning the following question:

I have a hash:

my %languages = (
                        ASM => 'Assembler',
                        PL => 'Perl',
                        C => 'C',
                        JV => 'Java',
                        VB => 'Visual Basic',
                        DLP => 'Delphi',
                );
[download]

and an array: my @employee = ('PL', 'VB', 'C'); What I want to do is come up with an array containing those unmatched keys from the hash. That is, in my example:

my @result = ('ASM', 'JV', 'DLP');

I'm looking for a smart way to achieve this. I could do it with a loop and compare type thing, but am sure there is a clever and better way to do it.

(Background info: it's for a HRM skills database. I've read in the skill records for an employee, and want to put a text box at the top of the form from which they can add a new skill to their records).

*~-}hotyopa{-~*

Comment on Find unmatched between an array and a hash Select or Download Code

Replies are listed 'Best First'.
Re: Find unmatched between an array and a hash by japhy (Canon) on Feb 07, 2001 at 06:06 UTC
I would do this: `my %copy = %hash; delete @copy{@array}; my @left_over = keys %copy;` [download] If you don't mind being destructive to `%hash`, you can just delete from there. `japhy` -- Perl and Regex Hacker	[reply] [d/l]
Re: Find unmatched between an array and a hash by Fastolfe (Vicar) on Feb 07, 2001 at 05:49 UTC
See How do I compute the difference of two arrays? How do I compute the intersection of two arrays?. I'd try finding the difference between `keys %languages` and `@employee`.	[reply] [d/l] [select]
Re: Find unmatched between an array and a hash by eg (Friar) on Feb 07, 2001 at 05:46 UTC
You can use nested greps. `my @result = grep { my $lang = $_; ! grep { $lang eq $_ } @employee } +keys %languages;` [download] alternatively you can use Quantum::Superpositions	[reply] [d/l]
Re: Re: Find unmatched between an array and a hash by merlyn (Sage) on Feb 07, 2001 at 06:16 UTC
Please don't. That'll be `O(n**2)` inefficient. -- Randal L. Schwartz, Perl hacker	[reply]
(tye)Re: Find unmatched between an array and a hash by tye (Sage) on Feb 07, 2001 at 10:10 UTC
This isn't slick, but it is straight-forward and seems like it should be fairly fast: `my @result= do { my %temp; @temp{@employee}= (); grep ! exists $temp{$_}, keys %languages; }` [download] Then again, with Perl and an N of 6, I don't think O(N*N) is much of a problem. ;) - tye (but my friends call me "Tye")	[reply] [d/l]