I'm not really following what you are trying to do, but it sounds to me like you need either a Hash of Arrays or an Array of Hashes (where the hashes are a single key => value pair and the value is your array) if you need to preserve order.

#!/usr/bin/perl -l

use strict;
use warnings;

my %unordered = (
    foo => [qw(foo baz baz)],
    bar => [0 .. 9],
);

print for @{ $unordered{foo} };


print "--------";

my @ordered = (
    { foo => [qw(foo baz baz)] },
    { bar => [0 .. 9] },
);

print for @{ $ordered[1]->{bar} };
[download]

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

This reply apples to at least two of the above entries, the third I haven't had a chance to address. All of the data is being pulled in from a file of the following structure:

@array1=(
'entry1',
'entry2',
...
);

@array2=(
'entry1',
'entry2,
...
)

...
[download]

There are a few rules I have to follow here: 1. I can not modify the format of the data file - it is not static, nor do I 'own' it where I can change the way it's generated. 2. The arrays can not be in the script itself . I guess the whole question boils down to this, how can I have the following:

@combined = ( $opt_f );
[download]

..interpret the following:

$opt_f = '@array1,@array2'
[download]

As a list of arrays which are then combined, and not simply treat them as regular entries, strings "@array1", "@array2"?

if you absolutely must do it this way, here is how (use eval):

## this is an example, works just as well if these arrays come from a 
+require'd file
my @array1 = qw(a b c);
my @array2 = qw(d e f);

## again, just an example, works just as well if this comes from GetOp
+t
my $opt_f = '@array1, @array2';

## here is the magical and evil eval
my @combined = eval "$opt_f";

print "@combined\n";
[download]

That being said, have you considered an array of hashes. Since a hash is, at its simplest, an associative array, you can create an array with named hashes. But like I said before, without example data, its difficult to help you any further with organizing data.

Depending on how the datafile is structured (also something that would be helpful if you provide), you do something like the following:

@combined = split /,/, $opt_f;

Side note, I am a personal fan of using GetOpt::Std with the hash format this way I can always Data::Dumper all the options provided as opposed to just one at a time:

use Getopt::Std qw(getopts);
getopts('f:', \%opt);
if ($opt{'f'}) {  ... }
# Debug
print Dumper (\%opt);
[download]

Eric

my %arrays = (
    array1 => [qw( a b c )],
    array2 => [qw( d e f )],
);

my @combined = ( @{ $arrays{array1} }, @{ $arrays{array2} } );
[download]

see How can I use a variable as a variable name?

You rarely want to have a variable name itself be variable, for many good reasons. If you don't know how to do it, you probably don't really want it. (I'll insert a link to a node that describes the technique and caveats as soon as I [id://Super Search|find it] again. Also, I'm not being snotty, I don't know how to do it either.)

However, the technique described by madbombX and mreece is usually the best way to do the job. Here's a quickie example on how to use the technique:

#!/usr/bin/perl -w
use strict;
use warnings;

my %hr = (
    'default' => [ 1 .. 9],
    'even'    => [ 0, 2, 4, 6, 8],
    'odd'     => [ 1, 3, 5, 7, 9],
);

my $arrname = shift || 'default';

print "Array $arrname contains:\n";

my $ar = $hr{$arrname};
for my $cnt (0 .. $#{$ar}) {
    printf "\t %s[%d]=%s\n", $arrname, $cnt, $ar->[$cnt];
}
[download]

Running this yields:

roboticus@swill ~/PerlMonks
$ ./var_array_names.pl  even
Array even contains:
         even[0]=0
         even[1]=2
         even[2]=4
         even[3]=6
         even[4]=8

roboticus@swill ~/PerlMonks
$ ./var_array_names.pl  odd
Array odd contains:
         odd[0]=1
         odd[1]=3
         odd[2]=5
         odd[3]=7
         odd[4]=9
[download]

--roboticus

UPDATE: Yarch! I was a bit slow, and several people beat me to the punch. Oh, well. Anyway, here are links to a few of the threads describing the pro & cons:

print eval('@'.$string.'[0]');

In your case, I think what you're looking for is something like:

foreach $entry ( @combined ) {
my $array = eval('\@'.$entry);
}
[download]

You can do similar incredibly ugly and horribly unrecommended things with eval, but if it gets the job done, it does ;)

I think you can use map to do something similar (see Perl Best Practices pg. 161 "Avoid string eval") which states this kind of behavior is best avoided.

Why are you not using a hash?

From the Getopt::Stddocumentation: "getopt() and getopts() will also accept a hash reference as an optional second argument. Hash keys will be x (where x is the switch name)".