Sounds like you're looking for split.

while (my $record = <EMPLOYEES>) {
  chomp $record;
  my @person = split /\t/, $record;
  # now do something interesting with @person
}
[download]

Actually I think I'd use a hash:

my @cols = qw(name email office);
while (my $record = <EMPLOYEES>) {
  chomp $record;
  my %person;
  @person{@cols} = split /\t/, $record;
  # now do something interesting with %person
}
[download]

Oh, and you should really be checking the return value from open and taking appropriate action.

open (EMPLOYEES, 'employees.txt')
  or die "Can't open employees.txt: $!\n";
[download]

use DBI;
my $dbh = DBI->connect("DBI:CSV:f_dir=.;csv_sep_char=\t") or die "Cann
+ot connect: " . $DBI::errstr;
$dbh->{'csv_tables'}->{'employees'} = { file => 'employees.txt'};

# now you have your choice of DBI commands.  This one gets a ref to a 
+Array of Hashrefs
my $aref = $dbh->selectall_arrayref("select * from employees", {Slice=
+>{}}, );  # AoH

$dbh->disconnect();
[download]

package My::Employees;
use base qw/Class::DBI/;
__PACKAGE__->connection("DBI:CSV:f_dir=.;csv_sep_char=\t",);
__PACKAGE__->db_Main->{'csv_tables'}->{'employees'} = { file => 'emplo
+yees.txt'};  # i'm guessing a little here .. it's a lot easier if the
+ file doesn't have an extension
__PACKAGE__->table('employees');
__PACKAGE__->columns(Primary => qw/NAME/ );  # is it unique??
__PACKAGE__->columns(All => qw/NAME EMAIL OFFICE/);

package main;
my @all = My::Employees->retrieve_all;
my $first = $all[0];
warn $first->EMAIL;
[download]

my $dbh = DBI->connect("DBI:CSV:f_dir=.;csv_sep_char=\t") or die "Cannot connect: " . $DBI::errstr;

I had a hard time trying the DBD::CSV example, until I saw in the documentation that the default value for csv_eol was \015\012 (I'm on Unix, so \n has other value here). When I stuck a csv_eol=\n to that line everything started to work.

Later I thought it would also be safe for Windows or Mac users to specify the csv_eol explicitly, since \n would map to the correct sequence of characters for the architecture. However, I haven't seen anyone recommending this ("Use always csv_eol=\n, unless working with files from other platforms"), maybe because there's a good reason for not doing so. Is there any?

Update: Fixed typo spotted by planetscape.

--
David Serrano

Thereby hangs a tale. I inherited DBD::CSV from Jochen Weidman back in 1999 and at that time it already had many users. Jochen had decided on using windows-style eol as the default because the primary intended audience was users of Excel. I left the default as-is in DBD::CSV for backward compatibility but in my DBD::AnyData I changed the default to be "\n" (i.e. the line ending on the platform where the script is being run) which usually works better except when people get files from elsewhere. So, in short, no, always using "\n" is not a bad idea.

Hmm, well I'll give it a go... you say tab seperated, but it's hard to know from the sample whether these have been transformed to spaces or not, so the following should work in either case.

Personally, although an elegant idea, I wouldn't use a hash here (it would dump you in the deep end with regard to references, etc.).

my $office = 'boston'; #office to match on
my @matched;
open(EMPLOYEES, 'employees.txt');
while(<EMPLOYEES>){
  chomp;
  if(/(.*?)\s*(\S*@\S*)\s*(.*$office.*)/i){
    push @matched, "$1 $2";
  }
}

print "Employees from $office office:\n";
foreach(@matched){
  print "$_\n";
}
[download]

use strict;
use warnings;

my $office = shift or die "Usage: $0 office\n";

my %h;

my $infile = "employees.txt";
open F, "< $infile" or die "read $infile - $!\n";

while (<F>)
{
    chomp;
    my( $name, $email, $offices ) = split /\t/;
    $offices or next;
    $h{$_}{$name} = $email
        for split /,\s*/, $offices;
}

close F;

print "$_\t$h{$office}{$_}\n"
    for sort keys %{ $h{$office} };
[download]