Do you mean something like this? I'm not sure I completely understand what you want to achieve.

use Tk;

my $mw = MainWindow->new;
$mw->bind('<KeyPress>', \&keyPress);
$mw->withdraw;

my ($lastX, $lastY);
$mw->repeat(400, [\&checkMouse, \$lastX, \$lastY]);
$mw->focusForce;

MainLoop;

sub quit {
   print "User triggered event -- exiting!\n";
   exit;
}

sub checkMouse {
   my ($lastX, $lastY) = @_;

   my $x = $mw->pointerx;
   my $y = $mw->pointery;

   $$lastX = $x unless defined $$lastX;
   $$lastY = $y unless defined $$lastY;

   quit() if $x != $$lastX;
   quit() if $y != $$lastY;
}

sub keyPress {
   quit();
}
[download]

Other ideas... if you're using X-Windows, you might have a look at X11-IdleTime, you could call that from the repeat sub. You might also tie something in to your screensaver hook, so that it pops open a window, displays it and acts as a kind of an alert asking the user if he wants to keep the user session.

You'll probably want to build some sort of timer in case the user does nothing, and allow the session to die. I'm generally pretty leery about hacks designed to keep user sessions open. of thing. Having sessions expire is a good thing, although if that session time is too short, then it can be irritating. Too long, and it can effectively be a memory leak.

If you're looking for any mouse movement, you could also just bind to the "<Motion>" event.  That would simplify your code even more:

use Tk;

use strict;
use warnings;

my $mw = MainWindow->new;
$mw->bind('<KeyPress>', \&keyPress);
$mw->bind('<Motion>',   \&mouseMotion);
MainLoop;

sub quit {
   print "User triggered event -- exiting!\n";
   exit;
}

sub keyPress {
   print "Debug:  keypress occurred\n";
   quit();
}

sub mouseMotion {
   print "Debug:  mouse motion occurred\n";
   quit();
}
[download]

---

s''(q.S:$/9=(T1';s;(..)(..);$..=substr+crypt($1,$2),2,3;eg;print$..$/

Yep - I didn't think to try it out. For some reason, I was thinking it would only trigger events if it was over the widgets that had the binding.

Thanks,

Rob

I'm not sure I completely understand what you want to achieve.

My bad, throwing too much thin client jargon around. I have a wrapper script for the screensaver. I check if someone is using a thin client and if they are I disconnect the session instead of running the actual screensaver. Disconnected sessions remain running on the server until the user reconnects from a thin client (could be the same one or could be a different one). Think Citrix or Windows Terminal Services (I list Citrix first because guess who Microsoft got the technology from.... ;-)

Management wants idle sessions locked or disconnected after 30 minutes. The problem is several users are looking at informantion on the thin client but not actually using them so the idle timeout kicks in and the session gets disconencted. Reconencting is annoying -- it's several seconds slower than just unlocking a screen saver. Thus, this script to warn them before it happens.

Thanks for the help!!

#!/usr/bin/perl
use warnings;
use strict;
use Tk;

my $mw = MainWindow->new;

#my $width =  $mw->screenwidth; 
#my $height = $mw->screenheight; 
#$mw->geometry($width . 'x' . $height .'+0+0'); 

$mw->bind('<Motion>', [\&activity ,'mouse']);
$mw->bind('<Key>', [ \&activity, Ev('K')]);

$mw->after(500,sub {$mw->grabGlobal}); #window must be visible 
$mw->focusForce;                       #for grab 

MainLoop;

sub activity {
    if( $_[1] eq 'Escape'){ exit }
  print chr(07); #beep 
}
[download]

Thanks zentara, the grabGlobal was the last thing I needed!! And thanks to everyone for the help!! My users will love you!! :-)