use IO::Handle;

my $file = 'output.dat';

open(OUTPUT, ">$file")   || die $!;
STDOUT->fdopen(\*OUTPUT, "w")  || die $!;

open STDERR, ">&STDOUT";

print        "This is STDOUT\n";
print STDERR "This is STDERR\n";
warn         "This is a warning\n";
[download]

Update: Cleaner:

my $file = 'output.dat';

{
   open(my $fh_out, '>', $file)
      or die("Unable to create output file \"$file\": $!\n");
 
   local *STDOUT = $fh_out;
   local *STDERR = $fh_out;

   print        "This is STDOUT (1)\n";
   print STDERR "This is STDERR (1)\n";
   warn         "This is a warning (1)\n";
}

print        "This is STDOUT (2)\n";
print STDERR "This is STDERR (2)\n";
warn         "This is a warning (2)\n";
[download]

If you want child processes to inherit STDOUT and STDERR:

use v5.8.0;

my $file = 'output.dat';

{
   open(my $fh_out, '>', $file)
      or die("Unable to create output file \"$file\": $!\n");
 
   local *STDOUT; open(*STDOUT, '>&', $fh_out)
      or die("Unable to redirect STDOUT: $!\n");

   local *STDERR; open(*STDERR, '>&', $fh_out)
      or die("Unable to redirect STDERR: $!\n");

   print        "This is STDOUT (1)\n";
   print STDERR "This is STDERR (1)\n";
   warn         "This is a warning (1)\n";
}

print        "This is STDOUT (2)\n";
print STDERR "This is STDERR (2)\n";
warn         "This is a warning (2)\n";
[download]

Thanks ikegami, that did the trick.

From open:

# First, save STDERR in case you need it later.
open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";

# Second, dupliate STDOUT, by pointing STDERR to it.
open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";

print STDOUT "My test string.\n";
[download]

sub create_logfile
{
    my (
        $logfile,   # final logfile name
        $filename,  # filename sans extension
        $filext,    # filename extension
        $filedir    # dir for logfile
        );

    # Get filename components
    ($filename, $filedir, $filext) = fileparse($0, '\..*');

    # Create filename
    $logfile = "${filedir}log/$filename.log";

    # Redirect STDOUT & STDERR to named logfile
    open( STDOUT, ">$logfile") or
                        die "\nUnable to open logfile $logfile: $!\n";
    open( STDERR, ">>&STDOUT");

    # Set autoflush on
    select (STDERR); $| = 1;
    select (STDOUT); $| = 1;
}
[download]

Cheers
Chris

open (STDERR, ">&STDOUT");
[download]

Same thing...STDERR never gets written to the file, only the terminal

use strict;
use warnings;

use IO::Handle;

my $file = 'C:\Progra~1\Ethereal\output.dat';

open (STDERR, ">&STDOUT");

open (OUTPUT, ">$file")   || die $!;
STDOUT->fdopen(\*OUTPUT, "w")  || die $!;

print "This is STDOUT\n";
warn "This is a warning\n";
[download]

Please ignore my answer, sorry!
My test script didn't work very well, so nothing was printed, which made me a little bit to enthousiastic :)

LuCa