Most elegant way to dispose of duplicates using map

rashley has asked for the wisdom of the Perl Monks concerning the following question:

Hello monks!

I have this sub, that takes a cgi param and splits it up into a list of hashes:

sub extractPartTuplesFromURL
  {
    my $cgi = shift;
    my @partTuples = $cgi->param('partID');
    
    @partTuples = map { my @t = split(','); 
                        {id=>$t[0],
                         version=>$t[1],
                         classification=>$t[2]} 
                      } @partTuples;

    return \@partTuples;
  }
[download]

What I need to do is get rid of the duplicates bassed on "id", or better yet, prevent them from getting in my list to begin with.

I'm sure I could slug through this, but everything I've come up with is very clunky, and I'm sure there is a more "monkish" way to do it.

Thoughts? Thanks!

Comment on Most elegant way to dispose of duplicates using map Download Code

Replies are listed 'Best First'.
Re: Most elegant way to dispose of duplicates using map by davorg (Chancellor) on Oct 30, 2006 at 16:26 UTC
The FAQ How can I remove duplicate elements from a list or array? can be adapted for use here. `my %seen; @partTuples = grep { ! $seen{$_->{id}}++ } @partTuples;` [download] -- <http://dave.org.uk> "The first rule of Perl club is you do not talk about Perl club." -- Chip Salzenberg	[reply] [d/l]
Re^2: Most elegant way to dispose of duplicates using map by rashley (Scribe) on Oct 30, 2006 at 16:33 UTC
Perfect, this is exactly what I was looking for. Thanks!	[reply]
Re^3: Most elegant way to dispose of duplicates using map by rashley (Scribe) on Oct 30, 2006 at 21:18 UTC
Just for the sake of intelectual growth, how could one tweak this to eliminate duplicates of id/versions pairs, instead of just id?	[reply]
Re^4: Most elegant way to dispose of duplicates using map by johngg (Canon) on Oct 30, 2006 at 22:28 UTC
Re^5: Most elegant way to dispose of duplicates using map by exussum0 (Vicar) on Oct 31, 2006 at 14:43 UTC
Some notes below your chosen depth have not been shown here
Re^5: Most elegant way to dispose of duplicates using map by rashley (Scribe) on Oct 31, 2006 at 15:00 UTC
Some notes below your chosen depth have not been shown here
Re: Most elegant way to dispose of duplicates using map by borisz (Canon) on Oct 30, 2006 at 16:30 UTC
Hope this is what you have in mind. `sub extractPartTuplesFromURL { my $cgi = shift; my @partTuples = $cgi->param('partID'); my %dupes; @partTuples = map { my @t = split(','); $dupes{ $t[0] }++ ? () : +{ id => $t[0], version => $t[1], classification => $t[2] } } @partTuples; return \@partTuples; }` [download] Boris	[reply] [d/l]
Re: Most elegant way to dispose of duplicates using map by davidrw (Prior) on Oct 30, 2006 at 18:03 UTC
Based on: Tutorials Perl Idioms Explained Perl Idioms Explained - keys %{{map{$_=>1}@list}} maybe something like (has similarities to the other solutions as well): `sub extractPartTuplesFromURL { my $cgi = shift; return values %{{ map { my %h; @h{qw/id version classification/} = split(','); $h{id} => \%h } $cgi->param('partID') }}; }` [download]	[reply] [d/l]
Re: Most elegant way to dispose of duplicates using map by Anonymous Monk on Oct 31, 2006 at 09:22 UTC
I find the most elegant way to remove duplicates is to not use map: `my %tmp; @tmp{@partTuples} = (); @partTuples = keys %tmp;` [download] Although I would use map if there was a need to keep the order.	[reply] [d/l]
Re: Most elegant way to dispose of duplicates using map by Anonymous Monk on Oct 31, 2006 at 15:58 UTC
Assuming that What I need to do is get rid of the duplicates bassed on "id" means that you should not have two items with the same id, and also assuming that the returned order doesn't matter, I'd use: `sub extractPartTuplesFromURL { my $cgi = shift; my %partTuples; foreach my $tuple ($cgi->param('partID')) { my($id, $version, $classificiation) = split(/,/, $tuple); next if $partTuples{$id}; # Keeps the first entry. Remove it i +f you want to keep the last. $partTuples{$id} = [$version,$classificiation]; } map {{id => $_, version => $partTuples{$id}->[0], classification = +> $partTuples{$id}->[1]}} keys %partTuples; }` [download] Or just return \%partTuples and change the caller.	[reply] [d/l]