For imsx, you can use (?switches:pattern). For g, you'll have to use an if.

my $source = "abc";
my $find = "a";
my $replace = "x";
my %opts = (
   i => 1,
   m => 0,
   s => 0,
   x => 0,
   g => 1,
);

my $opts = join '', map { $opts{$_}?$_:'' } qw( i m s x );
my $re = "(?$opts:$find)";

if ($opts{g}) {
   $source =~ s/$re/$replace/g;
} else {
   $source =~ s/$re/$replace/;
}

print $source;
[download]

Update: Fixed where %opts was referenced as %opt.

Build up your regular expression programatically, and use the (?i-xsm) or (?-xism) constructs (documented in perlre).

In other words....

my $insensitive = '(?i-xsm)';
my $sensitive   = '(?-xism)';

my $target = "Abcde";

foreach my $re_switch ( $insensitive, $sensitive ) {
    if( $target =~ m/$re_switch([a-z])/ ) {
        print "$1\n";
    }
}
[download]

And the output...

A
b
[download]

See perlop, namely qr/PATTERN/options. With qr// you can change imosx options as you wish within dynamically generated patterns.

I read your comment as meaning you can set the regex options from variables when using qr//. However, none of the following work for me:

$mods = "im";

$test = qr/xyz/$mods;   # Syntax error.
$test = qr/xyz/"$mods"; # Ditto.
$test = qr/xyz/\$mods;  # Ditto.
                        # ... out of ideas.
[download]

Could you clarify your post? What can you do with qr// and modifiers that you can't with m// or s///?

Nothing. Maybe he was thinking of the following:

# XXX WRONG DON'T USE THIS
$re = qr/$re/i if $opt{i};
$re = qr/$re/m if $opt{m};
$re = qr/$re/s if $opt{s};
$re = qr/$re/x if $opt{x};
[download]

On the other hand, the following does work:

$re = "(?i:$re)" if $opt{i};
$re = "(?m:$re)" if $opt{m};
$re = "(?s:$re)" if $opt{s};
$re = "(?x:$re)" if $opt{x};
[download]

$source = "abc";
$find = "a";
$replace = "x";
$opt = "g";
eval "\$source =~ s/$find/$replace/$opt";
print $source;
[download]

Better:

eval "\$source =~ s/\$find/\$replace/$opt";
[download]

Even better:

$opt =~ /[^imsx]/
   and die(...);

eval "\$source =~ s/\$find/\$replace/$opt";
[download]