Most likely because there is no file cica2061205.gz in the current directory. Or because the @| array contains something that makes the file match. Or something else. Why don't you try and break the regular expression down and sprinkle the code with debug messages to see closer what's going on?

# filter any unwholesome file names 
my @reason;
push @reason, "... a file with that name doesn't exist"
    if ! -f $file;
push @reason, "... it starts with a dot"
    if $file =~ /^\./;
...

if (@reason) {
    warn "Rejecting filename '$file' because ";
    warn $_ for @reason;
    next;
};
[download]

Also, it is a much saner approach to only allow what is permitted instead of rejecting what you know is bad. For example, I would simply just allow sane filenames, instead of trying to weed out not-so-sane filenames:

$file =~ /^\w[-_\w]+\.\w+$/
    or push @reason, '... it doesn't look like a sane filename';
[download]

Cheers,

JohnGG

Your alternation \$|&|<|>|@|\/ would be better expressed as a character class [$&<>@/].

Not really, no:

use strict;
use warnings;

my $name = 'whatever';
print $name =~ /[$&<>@/]/ ? 'Yep!' : 'Nope!';
[download]

Output:

Unmatched right square bracket at C:\Perl\progs\junk.pl line 5, at end
+ of line
syntax error at C:\Perl\progs\junk.pl line 5, near "/[$&<>@/]"
Search pattern not terminated or ternary operator parsed as search pat
+tern at junk.pl line 5.
[download]

Drat! Let's escape that pesky slash:

my $name = 'whatever';
print $name =~ /[$&<>@\/]/ ? 'Yep!' : 'Nope!';
[download]

Output:

Use of uninitialized value in concatenation (.) or string at junk.pl l
+ine 5.
Nope!
[download]

What's happening now? Ah, perl seems to think that $& means $MATCH. Why can't it DWIM? Let's try this:

my $name = 'whatever';
print $name =~ /[&$<>@\/]/ ? 'Yep!' : 'Nope!';
[download]

Aah, that's better!

Update: fixed typo, closed blockquote tag.

Update 2: just realised that there's yet another problem. The dollar sign has to be escaped as well:

my $name = 'what$ever';
print $name =~ /[\$&<>@\/]/ ? 'Yep!' : 'Nope!';
[download]

Yes, that was stupid of me. Thank you for pointing out my error.

Part of it is that I always use m{ ... } rather than / ... / so I have lost the habit of escaping slashes. The other part is I didn't realise that there was interpolation inside a character class so, as you point out, I failed to escape the $. Ought to do the @ as well, I suppose. Not sure about the &?

$ perl -le '
> use strict; use warnings;
> print q{whatever} =~ m{[\$&<>\@/]} ? q{Yep} : q{Nope};'
Nope
$ perl -le '
> use strict; use warnings;
> print q{v$table} =~ m{[\$&<>\@/]} ? q{Yep} : q{Nope};'
Yep
$ perl -le '
> use strict; use warnings;
> print q{bill@bloggs.com} =~ m{[\$&<>\@/]} ? q{Yep} : q{Nope};'
Yep
$
[download]

Cheers,

JohnGG