Here is an implementation using PadWalker:

use PadWalker qw( peek_my peek_our );
use strict;
use warnings;

sub name(\[$@%&*]) {
    for my $pad ( peek_my(1), peek_our(1)) {
        while (my ($k,$v) = each %$pad) {
            if ($v == $_[0]) {
                return $k;
            }
        }
    }
    return;
}




our $x = [0];
my @a = (1,2);
my %foo = (1 => 2);
my $subref = sub {};


printf "Name: %s\n", name($x);
printf "Name: %s\n", name(@a);
printf "Name: %s\n", name(%foo);
printf "Name: %s\n", name($subref);
[download]

Note that this will not work on older perls that do not support the (\[$@^&*]) style prototype.

It didn't seem fair (or fun) to provide a PadWalker example, and not a Filter::Simple one. I don't recommend using either of these approaches, but here is a basic(?) filter implementation: ShownameFilter.pm

package ShownameFilter;
use Filter::Simple;

FILTER_ONLY code => sub {
    s{
    showname\(
      (                # Capture 2 (closes second)
          \s*
          \\?          # References
          [\$@%*]+     # Scalar, array, hash, glob
          (            # Capture 1 (closes first)
           \w*         # alphanumeric. Doesn't catch a lot of perl spe
+cial vars
          )            # End capture 1
          \s*
      )                # End capture 2
      \)
    }
    {showname('$2',$1)}xg;
};

1;
[download]

showname.pl

use strict;
use warnings;
use ShownameFilter;

sub showname {
    my ($name,$value) = @_;
    print "name: $name\n";
}

my ($x, $x12, @foo, %bar);

showname($x);
showname( $x12 );
showname( \$x12 );
showname( @foo );
[download]

Output:

name: x
name: x12
name: x12
name: foo
[download]

Again - I don't recommend doing this.

Thank you imp

Your insight is truly appreciated. I tried Data::Dumper::Simple and except for pretty printing a hash (name => value where the fat comma "=>" lines up in a vertical column), it does what I was trying to achieve with my 3 subs showvar(),show(),showHASH

Incidently, the author Curtis "Ovid" Poe explains in more detail the reasons why people like myself would want to use his module as a simple debugging aid. ie. typos and "succintness"

Best regards

Bernie in Montreal.

If this is for tracing variables/values for debugging purposes, take a look at Smart::Comments. It's a source filter, but when you turn debugging off for production use, you do it by commenting out the use line, so there is no source filter used in the production code.

To trace a variable by name, you simply place the name of the var in a comment and when you use S::C, it will trace the name and value of the variable to STDERR.

c:>perl -MSmart::Comments
$var = 123;
### $var
$x = 'fred';
### $x
^Z
### $var: 123
### $x: 'fred'
[download]

It does a lot more besides.

  # In Perl, I type:
  %some_hash, $some_scalar, @some_list, some_func()

  # and then hit Ctrl-K to turn it into:

  print STDERR "DBG 950($$): ([\%some_hash, \$some_scalar, \@some_list
+, some_func()]):\n\t", Dumper([\%some_hash, $some_scalar, \@some_list
+, some_func()]);
[download]

nmap <C-K> <ESC>!!print_perl_debug STDERR %<RETURN>:w<CR>
[download]

#!/usr/bin/perl -w

$handle = shift || 'STDERR';
$file   = shift || '/dev/null';

$is_php = system(q(grep -q '^<\?PHP$' ) . $file) == 0;

if ($is_php)
{
    while (<STDIN>)
    {
        chomp;
        s/(^\s*)//;
        $space = $1;
        $rand = int(rand 900) + 100;
        print qq(${space}print 'DBG $rand: $_: ' . "[$_]\\n";\n);
    }
}
else
{
    $do_use = system "grep -q '^[^#]*use Data::Dumper' $file";
    while (<STDIN>)
    {
        chomp;
        s/(^\s*)//;
        $space = $1;
        $use = $do_use ? " use Data::Dumper;" : '';

        s/([@%])/\\$1/g;
        s/\$\\\@/\$\@/g; # fix up $@
        $_ = "[$_]" if /,/;
        $rand = int(rand 900) + 100;
        $printable = $_;
        $printable =~ s/(\$|")/\\$1/g;
        my $last = /\S/ ? qq(($printable):\\n\\t", Dumper($_);$use\n) 
+: qq(\\n";\n);

        print $space, 'print ', ($handle eq 'STDOUT' ? '' : "$handle "
+),
                    qq{"DBG $rand(\$\$): $last};
    }
}
[download]