Re: in, ands, ors in query

I hope you've gotten the syntax fixed by now so that it's working -- the replies above are clear enough about what the problem is. Once you have it working, you might think about some "stylistic" improvements:

my @getfields = qw/engine/;
for my $type ( qw/name lable settings/ ) {
    for my $num ( 1 .. 4 ) {
        push @getfields, "$type$num";
    }
}
my $sql = 'select '.
          join( ',', @getfields ).
          ' from special_fields WHERE engine IN ('.
          join( ',', ('?') x scalar @choices ).
          ') AND ('.
          join( ' OR ', map { "settings$_ = 'public'" } 1..4 ).
          ')';

my $sth = $dbh->prepare( $sql );
$sth->execute( @choices );
[download]

Notes:

"$data" is not a good name for a string that is supposed to store an SQL "select ..." statement;
having one array to store the names of all the columns being selected can be really handy later;
maybe the for loop for putting the names into an array is overkill, but it does save you from having to type the same names four times each;
you really should be using placeholders for variable values that are being plugged into the query, and passing those values when you execute the query;
formatting the lines of code for legibility in a narrower window can really help.

(update: having seen jdporter's reply, I have to agree -- his version is much easier to read)

Comment on Re: in, ands, ors in query Download Code

Replies are listed 'Best First'.
Re^2: in, ands, ors in query by jdporter (Paladin) on Dec 13, 2006 at 16:50 UTC
I personally find that style of sql construction hard to read. How about this: `my $sql = do { my $getfields = join ',', @getfields; my $placeholders = join ',', ('?') x @choices; my $settingspublic = join ' OR ', map "settings$_ = 'public'", 1 .. +4; <<EOF; select $getfields from special_fields where engine in ($placeholders) and ($settingspublic) EOF };` [download] We're building the house of the future together.	[reply] [d/l]

Replies are listed 'Best First'.

Re^2: in, ands, ors in query
by jdporter (Paladin) on Dec 13, 2006 at 16:50 UTC

I personally find that style of sql construction hard to read. How about this:

my $sql = do {
  my $getfields = join ',', @getfields;
  my $placeholders = join ',', ('?') x @choices;
  my $settingspublic = join ' OR ', map "settings$_ = 'public'", 1 .. 
+4;

  <<EOF;
  select $getfields
    from special_fields
    where engine in ($placeholders)
      and ($settingspublic)
EOF
};
[download]

We're building the house of the future together.

[reply]
[d/l]