m introduces a regex to be used for matching; whatever follows it is the delimeter around the regex. m!/([^/]+)$! would be exactly the same, as would m/\/([^\/]+)$/ (note that with / as the delimeter, /'s in the regex need to be escaped with \).

Please tell me how is the matching done?

The m#/([^/]+)$# matches a string of one or more non-slash characters at the end of a single-line string. (1) One or more is implied by +. (2) non-slash is implied by [^/]. (3) at the end of the string is implied by $. So when you feed the regex with $dir = "/exp/01jehandel/userinput/runwhennewfile", it matches runwhennewfile as you said.

Also what difference does putting brackets '()' for $thisj in its assignment statement makes?

The '()' capture the enclosed regex piece into the first group, $1. As a list assignment is being done, in ($thisj) = $dir =~ ..., that means the matching groups are returned to the left side value. But there's only one group here and $thisj will get its contents.

what is '#' doing here?

As the regex uses literal slashes (/), another delimiter was chosen (in the case, #). That what means m# ... #. Otherwise, it should have been written as /\/([^\/]+)$/ (which is hard to read).

You may learn more at perlretut and perlre.

• PerlMonks Tutorials on Pattern Matching and Regular Expressions
• Consider using File::Basename instead of a regex to achieve the same result.

use strict;
use warnings;

my $dir = q{/some/path/to/afile};
print qq{\nMatching $dir\n};

print qq{\nWith parentheses, list context\n};
my ($fileName) =
   $dir =~ m{([^/]+)$};
print
   defined $fileName
   ? qq{-->$fileName<--\n}
   : qq{Not defined\n};

print qq{\nWithout parentheses, scalar context\n};
$fileName =
   $dir =~ m{([^/]+)$};
print
   defined $fileName
   ? qq{-->$fileName<--\n}
   : qq{Not defined\n};

$dir = q{/some/path/with/no/file/};
print qq{\nMatching $dir\n};

print qq{\nWith parentheses, list context\n};
($fileName) =
   $dir =~ m{([^/]+)$};
print
   defined $fileName
   ? qq{-->$fileName<--\n}
   : qq{Not defined\n};

print qq{\nWithout parentheses, scalar context\n};
$fileName =
   $dir =~ m{([^/]+)$};
print
   defined $fileName
   ? qq{-->$fileName<--\n}
   : qq{Not defined\n};
[download]

Here's the output

Matching /some/path/to/afile

With parentheses, list context
-->afile<--

Without parentheses, scalar context
-->1<--

Matching /some/path/with/no/file/

With parentheses, list context
Not defined

Without parentheses, scalar context
--><--
[download]

I hope this is of use.

Cheers,

JohnGG

On the parenthesis in the lhs, see my $x or my ($x).

use re 'debug';
[download]