I see two hard parts here: resolving relative links and avoiding loops. For resolving relative links, File::Spec's rel2abs might help; notice you can give a base directory where the relative path should start from. For avoiding loops, many OS's just keep a count and give up after some number of symlinks; you could also track specific links in a hash and stop chasing links if you end up someplace you've been before.

I'm not sure whether you care about parent directories being symlinks, too. If so, that's a third hard part, though it's certainly manageable.

Here's some code to chase symlinks and print out what it finds, using rel2abs to deal with relative links and a hash to check for loops. I think it could be adapted to your needs.

#!/usr/bin/perl

use warnings;
no warnings 'uninitialized';

use strict;

use File::Spec qw(rel2abs);
use File::Basename;

chaselink($ARGV[0]);

sub chaselink
{
  my %seen = ();
  my $chase;
  $chase = sub {
    my($f,$d)=@_;
    print "\nChasing link '$f' in '$d'\n";
    my $l = readlink($f);
    if (!defined($l)) {
      print "$f is not a link.\n";
      return undef;
    }
    print "Relative link: $l from $d\n";
    my $a = File::Spec->rel2abs($l,$d);
    print "Absolute link: $a\n";
    if ($seen{$a}) {
      print "Found loop, giving up\n";
      return undef;
    }
    $seen{$a}=1;
    $chase->($a,dirname($a));
  };
  $chase->(@_);
}
[download]