A regular may not be the best choice there. Personally, I'd split and choose split and printf. There are many other choices.

my @a = split /\|/, $line;  # we still split with a regular ...
printf("%-43s %s\n", @a);
[download]

Contrast this:

use strict;
use warnings;
$/ = undef;

my $data = <DATA>;
$data =~ s{^(.*?)\|}{sprintf '%-45s', $1}meg;
print $data;

__DATA__
ABCDEFGHIJKLMNOPQRST|1234
ABCDEFGHI|12345
ABCDE|1234
ABCDEFGHIJKL|123
ABCDEFG|123456
ABCDEFGHIJKLMNO|12
[download]

use strict;
use warnings;

while (my $line = <DATA>) {
    my ($lhs,$rhs) = split /\|/, $line, 2;
    printf "%-45s%s", $lhs,$rhs;
}

__DATA__
ABCDEFGHIJKLMNOPQRST|1234
ABCDEFGHI|12345
ABCDE|1234
ABCDEFGHIJKL|123
ABCDEFG|123456
ABCDEFGHIJKLMNO|12
[download]

How about the best of both worlds?

while(<DATA>)
{
    s(\|){ ' ' x (45-pos) }e;
    print
}
[download]

A word spoken in Mind will reach its own level, in the objective world, by its own weight

Your dark arts frigten me.

-Paul

Another option.

#! perl -sw
use strict;

print pack 'A45 A*', split /\|/ while <DATA>;

__DATA__
ABCDEFGHIJKLMNOPQRST|1234
ABCDEFGHI|12345
ABCDE|1234
ABCDEFGHIJKL|123
ABCDEFG|123456
ABCDEFGHIJKLMNO|12
[download]

While both, jettero & imp, have provided perfectly suitable solutions for aligning two or more values using a formatstring, you perhaps might be interested what format offers, especially if you become interested in having multiple values output in a formatted way, where, for example, the alignment differs from value to value.

Example code

#!/usr/bin/perl

use strict;
use warnings;

my @elems = qw(left centered right);

format =
------------------------------------------
@<<<<<<<<<<<<< @||||||||||| @>>>>>>>>>>>>>
@elems
------------------------------------------
.

write;
[download]

outputs

------------------------------------------
left             centered            right
------------------------------------------
[download]

Update: Added code.