in reply to Regular expression help: why does this not match?

You're not stupid, after all you answered your own question correctly. The '?' in the first $b is indeed being interpreted as a metacharacter. To prevent this, use the \Q...\E codes in your regular expression (or the quotemeta builtin outside it): 

$a = "http://www.myurl.com/e.php?a";
$b = "http://www.myurl.com/e.php?a";
if ($a =~ /\Q$b\E/) {       # <---------
        print "FOUND\n";
} else {
        print "NOT FOUND\n";
}

[download]

Replies are listed 'Best First'.
Re^2: Regular expression help: why does this not match?
by lokiloki (Beadle) on Jan 18, 2007 at 23:11 UTC
    ah ha! \Q..\E is what i was looking for... however, its funny and a bit counter intuitive how this code still knows to interpret $b rather than simply going \$b
[reply]
[d/l]
[select]
      It may be surprising at first, but the idea is that it lets you construct regexps on the fly. One common thing this is used for is when you have a list of valid values you got from somewhere, say @valid, and you want to check a value against it: 

      my $valid = join "|", @valid;
print "okay" if /^$valid$/;

      [download]

      There are actually two improvements to make in the above code. First, the members of the valid list themselves might contain metacharacters in need of quoting; second, Perl has the qr// operator to make this more efficient: 

      # don't run this code on every match: the idea is the qr// needs
# to be computed only once.
my $valid    = join "|", map { quotemeta } @valid;
my $valid_re = qr/^$valid$/;

# now match as many times as you like.
print "$_: " . (/$valid_re/ ? "okay" : "not okay") . "\n"
        for @a_bunch_of_inputs;

      [download]
[reply]
[d/l]
[select]
        Bugfix: 
        my $valid_re = qr/^(?:$valid)$/;

        [download]
        Without the grouping there will be strange things happening ;-). Apart from that, depending on the situation, you might want to replace $ at the end of the regex with \z depending on whether you want to allow newlines behind the valid items (your solution) or not (\z).

        Update: To see the strange things happening, try 

        my @valid = qw/foo bar baz/;
my @a_bunch_of_inputs = qw/fooZZZ ZZbarZZ ZZZbaz foobaz foo bar baz/;

        [download]
        and all of the inputs will produce okay.

        -- Hofmator

        Code written by Hofmator and posted on PerlMonks is public domain. It is provided as is with no warranties, express or implied, of any kind. Posted code may not have been tested. Use of posted code is at your own risk.

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom