Most people have little trouble with running Tk on ActiveState ( there are the minor incompatibilities).

You can also avoid using getopenfile on windows with something like the following:

#!/usr/bin/perl
use strict;
use Tk;
require Tk::DirTree;
require Tk::Adjuster;
require Tk::TList;

# The initial directory
my $initial_dir = '/';

# The main window...
my $main = new MainWindow( -title => 'Explorer)' );

# A frame for the tree, adjuster and tlist
my $tree_adj_tablist = $main->Frame();
$tree_adj_tablist->pack(
    -expand => 'yes',
    -fill   => 'both',
    -side   => 'top'
);

# A scrolled directory tree
my $tree = $tree_adj_tablist->Scrolled(
    'DirTree',
    -width            => 35,
    -height           => 25,
    -scrollbars       => 'osoe',
    -background       => 'White',
    -selectmode       => 'single',
    -selectbackground => 'DarkBlue',
    -selectforeground => 'White',
    -showhidden       => 1,
    -directory        => $initial_dir
);
$tree->pack(
    -expand => 'yes',
    -fill   => 'both',
    -padx   => 2,
    -pady   => 2,
    -side   => 'left'
);

# An adjuster
my $adjuster = $tree_adj_tablist->Adjuster(
    -widget => $tree,
    -side   => 'left'
);
$adjuster->pack( -side => 'left', -fill => 'y' );

# A scrolled tab_list widget
my $tab_list = $tree_adj_tablist->Scrolled(
    'TList',
    -background => 'White',
    -orient     => 'vertical',
    -selectmode => 'extended',
    -scrollbars => 'os'
);
$tab_list->pack(
    -expand => 'yes',
    -fill   => 'both',
    -padx   => 2,
    -pady   => 2,
    -side   => 'right'
);


# Ok button 
my $ok = $main->Button(
    -text      => 'Ok',
    -underline => 0,
    -width     => 4,
    -command   => sub {  my $selected = $tab_list->info('selection');
                         #print "@{$selected}\n";
                         foreach( @{$selected} ){
              print $tab_list->entrycget($_, '-text'),"\n";
                         }
        })->pack( -side => 'right', -padx => 10, -pady => 10 );


# A Quit button (will be suppressed???...)
my $quit = $main->Button(
    -text      => 'Quit',
    -underline => 0,
    -width     => 6,
    -command   => sub { exit }
);
$quit->pack( -side => 'right', -padx => 10, -pady => 10 );



# Configuring tree and tab_list widgets...
$tree->configure( -browsecmd => sub { list_dir( $tab_list, @_ ); } );

# We list the content of the initial dir inside the tab_list
list_dir( $tab_list, $initial_dir );

MainLoop();

#---------------------------------------------------------------------
+-------

# Displays Dirs and files in TList widget
sub list_dir {
    my ( $tab_list, $path ) = @_;

    # Erase the TList content
    $tab_list->delete( 0, 'end' );

    opendir MY_DIR, $path or return;

    foreach my $file ( sort readdir(MY_DIR) ) {

        # Do not display '.' and '..'
        next if ( $file eq '.' or $file eq '..' );

        # Insert the files in the TList
        $tab_list->insert( 'end', -text => $file );
    }
    closedir MY_DIR;
}
[download]

thanks so much for the sample code. i'm still a little confused... you say that (mostly) Tk under ActiveState runs fine - does that imply that it does not use Win32? i'm not making the connection on where Win32 fits into the picture. I thought it would be necessary for any/all Tk calls (when i include the TK package, i thought the Win32 got included too).

also, this might be a dumb question, but why does your code execute fine when activestate executes it, but not when cygwin's perl executes it. with cygwin, the code runs, by a window, nor an error msg, ever appear. i eventually just kill'ed the process.

hope i'm not being too dense here. thanks for your time.