Or

my %hash = map { chomp; split ',', $_, 2 } <$fh>;
[download]

This does not work!

Data dumper returns:


$VAR1 = 'A';
$VAR2 = 'B,C';
$VAR3 = 'D';
$VAR4 = 'E,F';
$VAR5 = 'G';
$VAR6 = 'H,I';
[download]

Hi narashima,

Zaxo's solution actually does work.  I think you've made a mistake in the way you pass the data to Data::Dumper.

You need to pass a reference to the hash, not just the hash itself.

Try this:

use strict;
use warnings;
use Data::Dumper;

# Pretend that I've already read the file into @lines ...
my @lines = (
    'A, B, C',
    'D,E,F',
    'G, H,I',
);

# Zaxo's solution
my %hash = map { chomp; split ',', $_, 2 } @lines;

# View the data (use a *reference* to the hash, though!)
printf "Data => %s\n", Dumper(\%hash);
[download]

which correctly outputs the following...

Data => $VAR1 = {
          'A' => ' B, C',
          'D' => 'E,F',
          'G' => ' H,I'
        };
[download]

---

s''(q.S:$/9=(T1';s;(..)(..);$..=substr+crypt($1,$2),2,3;eg;print$..$/

use strict;
use warnings;

use Data::Dumper;

my %hash = 
   map { $_->[0] => join q{,}, @$_[1, 2] }
   map { chomp; [ split m{\s*,\s*} ] }
   <DATA>;

print Dumper \%hash;

__END__
A, B, C
D,E,F
G, H,I
[download]

The output

$VAR1 = {
          'A' => 'B,C',
          'D' => 'E,F',
          'G' => 'H,I'
        };
[download]

Cheers,

JohnGG

---
A:
 - B
 - C
D:
 - E
 - F
G:
 - H
 - I
[download]

#!/usr/bin/perl -w
use YAML;
use Smart::Comments '###';
my $data = YAML::LoadFile('text.conf');
### $data
[download]

### $data: {
###          A => [
###                 'B',
###                 'C'
###               ],
###          D => [
###                 'E',
###                 'F'
###               ],
###          G => [
###                 'H',
###                 'I'
###               ]
###        }
[download]

YAML rocks