Use a hash to check for hits from the smaller data set (A in the sample) and generate a composite list:

use strict;
use warnings;

my @DataA = split /\n/, <<DATAA;
A   "Monday"
B   "Tuesday"
C   "Wednesday"
D   "Thursday"
DATAA

my @DataB = split /\n/, <<DATAB;
M    252   212  "Bill"
A    325   908  "Jim"
C    426   907  "Mike"
A    423   383  "Sally"
A    993   421  "Jim"
C    737   432  "Mary"
DATAB

my %AHits;
my @merged;

for (@DataA) {
    my ($key, $day) = split /\s+/;
    
    $AHits{$key} = $day;
}

for (@DataB) {
    my ($key, @params) = split /\s+/;
    
    next unless exists $AHits{$key};
    
    push @merged, [$key, $AHits{$key}, @params];
}

print join ("\t", @$_), "\n" for sort {$a->[0] cmp $b->[0]} @merged;
[download]

Prints:

A    "Monday"    325    908    "Jim"
A    "Monday"    423    383    "Sally"
A    "Monday"    993    421    "Jim"
C    "Wednesday"    426    907    "Mike"
C    "Wednesday"    737    432    "Mary"
[download]

This is very nice, fairly straightforward and clean. I will see if I can implement this approach. Thanks a bunch!! Expo

This looks like something I'd pull out a bit of DBI and DBD::CSV (don't let the name fool ya - you should be able to use tabs or spaces or whatever as separators, not just commas), and a small bit of SQL for. I'm sure you could do faster by hand, but I'm not sure it would be as bug-free, nor would it be nearly so quick to develop.

#!/usr/bin/perl
use warnings;
use strict;
use Fcntl ':seek';


open DATASET_A, '<', 'File_A' or die "Cannot open 'File_A' $!";
open DATASET_B, '<', 'File_B' or die "Cannot open 'File_B' $!";


my %dataB;

my $tell = tell DATASET_B;
while ( <DATASET_B> ) {
    if ( /^(\S+)/ ) {
        push @{ $dataB{ $1 } }, $tell + length $1;
        }
    $tell = tell DATASET_B;
    }


while ( <DATASET_A> ) {
    chomp;
    my ( $key ) = /^(\S+)/;
    if ( exists $dataB{ $key } ) {
        for my $seek ( @{ $dataB{ $key } } ) {
            seek DATASET_B, $seek, SEEK_SET;
            print $_, scalar <DATASET_B>;
            }
        }
    }


__END__
[download]

Yet another way to do it:

You might want to sort both files on the key of interest. Then you can scan through the files side-by-side and print the appropriate items--just like a merge sort.

I recently responded to a similar question which you might want to look at if you're interested in this method--it has an example program in it that could easily be modified to handle your problem.

--roboticus

Thanks Roboticus, I will take a look!

Update: Hmm. Not reading carefully enough...join (Unix command line join, not perl function join) could be made to work, but you said you had arrays, though you did say you had enormous amounts of data...