use strict;
use warnings;

my %description_of = (
                      server1 => "Webserver",
                      server2 => "DMZ Server",
                      server3 => "Oracle Server",
                      );

my $DEFAULT_DESCRIPTION = "Unknown Server";

my @servers = qw(server1 server2 server3 server42);

for my $server (@servers) {
    printf "%s\n", get_description_of( $server );
}
exit( 0 );

sub get_description_of {
    my ($server) = @_;

    if (defined $description_of{ $server }) {
        return $description_of{ $server };
    }
    return $DEFAULT_DESCRIPTION;
}

__END__
[download]

Webserver
DMZ Server
Oracle Server
Unknown Server
[download]

Open the file into an array or hash?

Assuming I understand you correctly, and you are using a file of the format:

server1             Webserver
server2             DMZ Server
server4             Oracle Server
[download]

use strict;
use Tie::File;
  |
  mumble.
  |

sub get_comments {
   my $host=shift;
   my @ry=();
   tie @ry,"Tie::File","myfile.txt" or die "myfile.txt: $!";
   my @lines = grep $host,@ry;
   my $line = shift @lines;  # should only be one. 
   my @f=split(/[\s\n\t]+/,$line);
   shift @f;
   untie @ry;
   return join(" ",@f);
}
[download]

Hope this is a help...

Your ignored the fact that the search was case-insensitive.

my $host = lc(shift(@_));
[download]

Your grep is wrong.

my @lines = grep { lc($_) eq $host } @ry;
[download]

Why read the whole file everytime?

use List::Util qw( first );
my $line = first { lc($_) eq $host } @ry;
[download]

Why use Tie::File if you're not going to take advantage of it?

use List::Util qw( first );
my $line = first { lc($_) eq $host } <$fh>;
[download]

Why load up the entire file into memory if you look at it one line at a time?

sub get_comments {
   my $host = lc(shift(@_));
   my $file_name = "myfile.txt";

   open(my $fh, '<', $file_name)
      or die("Unable to open server info file \"$file_name\": $!\n");

   while (<$fh>) {
      return $1 if /^$host:\s*(.*)/;
   }

   return;
}
[download]

Of course, that's still very expensive if get_comments is called repeatedly. If the list is really that long, some sort of index (or database) would be very useful. A sorted file with fixed length records would also be fine (allowing for a binary search).

Why load up the entire file into memory if you look at it one line at a time?

Last I checked... Tie::File does not load the entire file into memory...

---

Peter L. Berghold -- Unix Professional
Peter -at- Berghold -dot- Net; AOL IM redcowdawg Yahoo IM: blue_cowdawg

I don't see how you'll get around the list of regulars. You can maybe make it slightly more efficient with something like $y = $1 if $x =~ m/(host1|host2|host3)/i perhaps; but, I think you'd need Benchmark to see if that actually helped.

If it was my code, and I was getting more than a few dozen lines or so, I'd probably start a table of pre-compiled host regulars or something like so:

# e.g. $hosts{'DMZ Server'} = qr{(?i:server2)};

while( my ($name, $reg) = each %hosts ) {
    return $name if $x =~ $reg;
}
[download]

Update: I just noticed this little bit, "separate the comment list from the actual script" You can definitely build the hash in a separate file like below, but I think if your list is getting really big, you should look at the packages mentioned in the post below mine. Both are pretty slick.

use MyHosts;

while( my ($name, $reg) = each %MyHosts::hosts ) { }

# ...

package MyHosts;

use strict;

our %hosts = (
  'Server Name' => qr(?i:serverpattern),
);
[download]