in reply to Convert delimited string into nested data structure

The name keys seem redundant to me. If you want to generate a nested hash structure based on the key strings then the following (non-recursive) code may get you started:

use strict;
use warnings;
use Data::Dump::Streamer;

my %hash;

while (<DATA>) {
    chomp;
    my @elements = split /\s*\/\s*/;
    
    next if ! @elements;
    
    $hash{$elements[0]} = {} if ! exists $hash{$elements[0]};
    my $subHash = $hash{shift @elements};
    
    for (@elements) {
        $subHash->{$_} = {} unless exists $subHash->{$_};
        $subHash = $subHash->{$_};
    };
}

Dump \%hash;

__DATA__
one
foo / bar
foo / baz
foo / qux / two
foo / qux / three
foo / qux / four
five

[download]

Prints:

$HASH1 = {
           five => {},
           foo  => {
                     bar => {},
                     baz => {},
                     qux => {
                              four  => {},
                              three => {},
                              two   => {}
                            }
                   },
           one  => {}
         };

[download]
DWIM is Perl's answer to Gödel

Replies are listed 'Best First'.
Re^2: Convert delimited string into nested data structure
by Anonymous Monk on Feb 19, 2007 at 20:30 UTC
    The output will be used in an HTML::Template loop, so the name keys are required. Thanks for trying anyways, but the output I gave is what I need, and this won't work for me. :(
[reply]

      Well why didn't you say so?

      use strict;
use warnings;
use HTML::Template;

use strict;
use warnings;
use Data::Dump::Streamer;

my %hash;

while (<DATA>) {
    chomp;
    my @elements = split /\s*\/\s*/;
   
    next if ! @elements;
   
    $hash{$elements[0]} = {} if ! exists $hash{$elements[0]};
    my $subHash = $hash{shift @elements};
   
    for (@elements) {
        $subHash->{$_} = {} unless exists $subHash->{$_};
        $subHash = $subHash->{$_};
    };
}

my @tree;

push @tree, buildFamily (\%hash, $_) for keys %hash;

my $template = <<'HTML';
  <html>
  <head><title>Test Template</title>
  <body><TMPL_LOOP NAME="Parents">
        Parent: <TMPL_VAR NAME="name"><br>
        <TMPL_LOOP NAME="children">   Child: <TMPL_VAR NAME="name"><br
+>
            <TMPL_LOOP NAME="children">   Grandchild: <TMPL_VAR NAME="
+name"><br>
        </TMPL_LOOP></TMPL_LOOP></TMPL_LOOP></body>
  </html>
HTML

my $t = HTML::Template->new (scalarref => \$template);

$t->param (Parents => \@tree);

print $t->output ();


sub buildFamily {
    my ($hash, $parent) = @_;
    my %root = (name => $parent);
    
    if (keys %{$hash->{$parent}}) {
        my @children;
        
        push @children, buildFamily ($hash->{$parent}, $_)
            for keys %{$hash->{$parent}};
            
        $root{children} = \@children;
    }
    
    return \%root;
}

__DATA__
one
foo / bar
foo / baz
foo / qux / two
foo / qux / three
foo / qux / four
five

      [download]

      Prints:

        <html>
  <head><title>Test Template</title>
  <body>
        Parent: five<br>
        
        Parent: one<br>
        
        Parent: foo<br>
           Child: bar<br>
               Child: baz<br>
               Child: qux<br>
               Grandchild: three<br>
           Grandchild: two<br>
           Grandchild: four<br>
        </body>
  </html>

      [download]
      DWIM is Perl's answer to Gödel
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom