In simple terms, use map for transformation and grep for filtering.

See the following code snippet

my @ints = qw(1 2 3 4 5);

my @doubleints = map { $_ * 2 } @ints;

my @odds = grep { $_ % 2 } @ints;

print "INTS = " . join(",", @ints) . "\n";

print "DOUBLE = " . join(",", @doubleints) . "\n";

print "ODDS = " . join(",", @odds) . "\n";


----------- OUTPUT ------
INTS = 1,2,3,4,5
DOUBLE = 2,4,6,8,10
ODDS = 1,3,5
[download]

Mahesh

returns a new list containing those elements of list for which expression or block produces a true value, whereas

map expression,-or-block list

performs the expression or block for each element of list and returns the list of values the expression produced (i.e. one (*!) for each element supplied in the "input" list).

Both of these update the default variable $_ with the current list element before executing the expression or block. Examples:

my @sources = grep /\.c$/, glob '*'; # get only the files ending in .c
+ from a listing of the working directory

my @objects = map s/\.c$/\.o/, @sources; # get the list of object file
+s that a c compiler would make by default from the files now in @sour
+ces

my @virgins = map { my $c = $_;
                    $c =~ s/\.o$/\.c/;
                    system "cc $c";
                    $c } grep !(-f), @objects;
                # find and compile the uncompiled sources
[download]

(i.e. one for each element supplied in the "input" list)

That's usually what happens but you can produce more than one "output" for each "input", like this for example

$ perl -le '
-> @list = map { ($_ - 1, $_, $_ + 1) } 3, 6, 9;
-> print qq{@list};'
2 3 4 5 6 7 8 9 10
$
[download]

Cheers,

JohnGG

Another key difference is right there in your OP (this expands on smahesh's remark)

• grep --- use it when you want to extract certain elements of a list based on certain criteria
• map --- use this when you want to do something to every element of a list

Note with both the difference in the return value depending on the context in which it's called.

perldoc -f grep

perldoc -f map

You may also wish to have a look at our Tutorials, specifically, Map: The Basics.

You want grep to remove rows, while map and List::MoreUtils's apply transforms rows.

When using grep or map, don't change $_ unless you want to change the original array.

apply is similar to map, but you can safely modify $_. The downside to using apply is that you're limited to 1:1 transformations (whereas map is extremely flexible).

use List::MoreUtils qw( apply );

my @orig    = qw( Just another Perl hacker );
my @grepped = grep  { /^[A-Z]/      } @orig;
my @mapped  = map   { uc            } @orig;
my @applied = apply { s/[aiueo]//ig } @orig;

print("@orig\n");     # Just another Perl hacker
print("@grepped\n");  # Just Perl
print("@mapped\n");   # JUST ANOTHER PERL HACKER
print("@applied\n");  # Jst nthr Prl hckr
[download]

List::MoreUtils can easily be installed if you're using ActivePerl. Just type by ppm install List-MoreUtils at the prompt