I can't reproduce your problem. Your code will print $line many times if more than one element of @all appears in $line. The following code eliminates the loop and replaces it with a single regular expression - maybe you can work from this example or show us data where this example doesn't do what you mean it should:

#!perl -wl
use strict;

my @all = qw( rsriram Corion );

my $re = sprintf '\b(?:%s)\b', join "|", map { quotemeta } @all;
$re = qr/$re/;
print "Searching for $re\n";

for (<DATA>) {
    chomp;
    if (/$re/) {
        print "Found at least one match in '$_'\n";
    } else {
        print "Ignoring '$_'\n";
    };
};

__DATA__
This is a line that mentions rsriram.
This is a line that mentions Corion.
This is a line that mentions Corion and rsriram together.
This is a line that mentions neither of the two.
This line intentionally left blank.
[download]

Can we see some sample input (both what is in $line and what is in @all). Your method isn't very Perlish, but it should work.

If you had "use warnings" in your code then you would be warned about using @all[$x] where you almost certainly mean $all[$x]. Also, you're probably better off using a "foreach" loop instead of the C-style loop you have here.

foreach (@all){ 
  if ($line =~ /$_/) {
    print F2 $line;
  }
}
[download]

If you're comparing with a lot of lines then you might find it faster to create a regex from all of the elements of @all.

my $re = join '|', @all;
$re = qr/$re/;

if ($line =~ /$re/) {
  print F2 $line;
}
[download]

Update: Corion's method of creating a regex is more robust than mine.

rsriram,

Change @all[$x] which is an array slice into $all[$x]which is a individual element in an array. The below is equivalent to your code.

for my $x (0..$#all)
{
    if($line =~ /$all[$x]/)
    {
        print F2 $line;
    }
}

simply:

foreach (@all)
{
  print F2 $line if $line =~ /$_/;
}
[download]