in reply to How to access a static hash.

Maybe someone really meant to say that 
my $hash = { a => 'b' };
$hash->{$x}

[download]
is just a lot more legible, intelligible, and therefor more maintainable than 
{a => 'b'}->{$x}

[download]
and in terms of programmer time (as opposed to execution time), the former could be a time saver overall. That's probably a matter of personal judgment and taste, but I'd be inclined to agree with it. Especially as you get into larger numbers of hash elements, IMO, keeping the initialization and the fetching of a value as separate statements seems easier and more intuitive, somehow.

Still, now that I've seen the latter idiom (no, I hadn't seen that sort of usage before), I can appreciate its attraction -- it's sort of like a clever substitute for the (chain of) ternary operator(s). Instead of this: 

sub some_function
{
    my ( $x ) = @_;
    return ( $x eq 'foo' ) ? "results for foo" :
           ( $x eq 'bar' ) ? "results for bar" :
           ( $x eq 'qaz' ) ? "results for qaz" : 
           " ... and so on, ad nauseum";
}

[download]
there's this: 
sub some_function
{
    my ( $x ) = @_;
    { foo => "results for foo",
      bar => "results for bar",
      qaz => "results for qaz",
    }->{$x} || "... and so on, ad nauseum";
}

[download]
It might be interesting to benchmark those alternatives, since they seem more "equivalent" (in terms of purpose) than the two you tested.

(updated to fix a typo, and to add the following benchmark script:) 

#!/usr/bin/perl

use strict;
use Benchmark qw(:all);

sub anonhash
{
    my ( $x ) = @_;
    { foo => "results for foo",
      bar => "results for bar",
      qaz => "results for qaz",
    }->{$x} || "... and so on, ad nauseum";
}
sub ternary
{
    my ( $x ) = @_;
    return ( $x eq 'foo' ) ? "results for foo" :
           ( $x eq 'bar' ) ? "results for bar" :
           ( $x eq 'qaz' ) ? "results for qaz" : 
           " ... and so on, ad nauseum";
}
my @strings = qw/foo bar baz qaz/;
my $i = 0;
cmpthese( -5, {
                anonhash => sub { anonhash( $strings[$i++] );
                                  $i = 0 if ( $i == @strings ) },
                ternary => sub { ternary( $strings[$i++] );
                                 $i = 0 if ( $i == @strings ) },
               } );

[download]
and the results: 
             Rate anonhash  ternary
anonhash  64869/s       --     -72%
ternary  232475/s     258%       --

[download]

Well, so much for being clever, I guess. ;)

One last update: I was still curious about "scalability": what happens as more distinct cases are needed? I adjusted my benchmark script by adding seven more hash keys to the anonhash function, and an equivalent set of seven more chained conditionals in the ternary function. Results: 

             Rate anonhash  ternary
anonhash  26893/s       --     -87%
ternary  204817/s     662%       --

[download]

Replies are listed 'Best First'.
Re^2: How to access a static hash.
by gam3 (Curate) on Mar 18, 2007 at 16:49 UTC
    What you did not test is the global hash: 
                  Rate   anonhash globalhash    ternary
anonhash   32323/s         --       -59%       -63%
globalhash 79642/s       146%         --        -8%
ternary    86652/s       168%         9%         --
    With only a few more entries the global hash would be faster. However you have to name each of these global hashes (and I am bad with names). 
    #!/usr/bin/perl

use strict;
use Benchmark qw(:all);

our $hash = {
  foo => "results for foo",
  bar => "results for bar",
  qaz => "results for qaz",
};
sub globalhash
{
    my ( $x ) = @_;
    $hash->{$x} || "... and so on, ad nauseum";
}
sub anonhash
{
    my ( $x ) = @_;
    { foo => "results for foo",
      bar => "results for bar",
      qaz => "results for qaz",
    }->{$x} || "... and so on, ad nauseum";
}
sub ternary
{
    my ( $x ) = @_;
    return ( $x eq 'foo' ) ? "results for foo" :
           ( $x eq 'bar' ) ? "results for bar" :
           ( $x eq 'qaz' ) ? "results for qaz" : 
           " ... and so on, ad nauseum";
}
my @strings = qw/foo bar baz qaz/;
my $i = 0;
cmpthese( -5, {
                anonhash => sub { anonhash( $strings[$i++] );
                                  $i = 0 if ( $i == @strings ) },
                ternary => sub { ternary( $strings[$i++] );
                                 $i = 0 if ( $i == @strings ) },
                globalhash => sub { globalhash( $strings[$i++] );
                                  $i = 0 if ( $i == @strings ) },
               } );

    [download]
    -- gam3
    A picture is worth a thousand words, but takes 200K.
[reply]
[d/l]

In Section Seekers of Perl Wisdom