To match your date format:

m{
  # any of the 12 months:
  (?: January   |
      February  |
      March     |
      April     |
      May       |
      June      |
      July      |
      August    |
      September |
      October   |
      November  |
      December
    )
    \s          # a space between month and day
    [123]?\d    # Is the first day 1, \s1, or 01?
    ,           # a comma between day and year
    \s?         # an optional space between comma and year
    [12]\d{3}   # a four digit year
}xms
[download]

Each \s can match a newline as well as a space. Normally I'd write \s+ and \s* to match multiple spaces and zero-or-more spaces, respectively, but your spec seems to indicate only one is expected. I wasn't sure how a single digit day is to be represented, so I made it a single digit. If it needs a leading zero or space, the pattern needs to account for that.

To match intervening tags, I'd make it like this:

m{
  # any of the 12 months:
  (?: January   |
      February  |
      March     |
      April     |
      May       |
      June      |
      July      |
      August    |
      September |
      October   |
      November  |
      December
    )
    (?:<.+?>|\s)*  # zero or more tag like things or spaces
    [123]?\d       # Is the first day 1, \s1, or 01?
    ,              # a comma between day and year
    (?:<.+?>|\s)*  # zero or more tag like things or spaces
    [12]\d{3}      # a four digit year
}xms
[download]

Note that this allows there to be no space between the month and day.

To extract the date from this, wrap the pattern in parentheses and take it from $1 afterward.

if ( $html =~ m{ ( blah blah as above blah blah ) }xms ) {
    my $date = $1;
    # remove the tags, if there are any
    $date =~ s/<.+?>//g;
}
[download]

I have not tested any of the above. Hope it helps.

We need a bit more information to go on though. Could you show some (short) samples of what your dealing with?

For instance, do you know what tags will be surrounding what you're looking for? Do you know what tags may be 'in' what you're looking for?

If you can let us know it would be easier to help.

For this sort of task I reach for mod?;;HTML::TreeBuilder. Consider:

use strict;
use warnings;
use HTML::TreeBuilder;

my $html = <<HTML;
<p>June <b>25, </b>1998</p>
<p>November 12,2006 September 21, 1999</p>
<p>December 36,
10</p>
HTML

my $tree = HTML::TreeBuilder->new_from_content ($html);

for ($tree->look_down ('_tag', 'p')) {
    my $text = $_->as_text ();
    print "$1\n" while $text =~ /(\w+\s+\d+,\s*\d+)/g;
}
[download]

Prints:

June 25, 1998
November 12,2006
September 21, 1999
December 36, 10
[download]

/s
Treat string as single line. That is, change "." to match any characte
+r whatsoever, even a newline, which normally it would not match.
[download]