As I said above, not that I really need this "feature", but is there a way to "inline" a subref as hinted above? Somehow it strikes me as as something that should be doable if not for anything else for completeness sake...

This topic comes up from time to time on p5p. The short answer is that while theoretically it makes sense from some sort of orthogonal point of view, the parser code is not particularly amenable in this respect. From memory it's got something to do with disambiguating curlies (is this a hash deref or a code block coming up).

That said, you can inline a subref lookup, if you are brave and insist on this approach. Given the package:

package Foo;

sub new {
    bless { val => $_[1] }, $_[0];
}

sub zug {
    my $self = shift;
    my $arg  = shift;
    return "$arg $self->{val} $arg";
}

sub zwang {
    my $self = shift;
    my $arg  = shift;
    return join( ' ', ($self->{val}) x $arg );
}
[download]

Then the tradtional as-per-perlop approach would be:

my $f = Foo->new('doot');
my @meth = (qw(zug zwang));

# doesn't work:
# print $f->$meth[rand @meth](3);

my $m = $meth[rand @meth];
print $f->$m(3), $/;
[download]

But you can avoid creating the intermediate lexical by dereferencing a scalar reference:

my $f = Foo->new('doot');

# update: with subrefs:
my @meth = (\&Foo::zug, \&Foo::zwang);

print $f->${\$meth[rand @meth]}(3);
[download]

But you have to admit that the traditional approach is a little easier for people to comprehend.

updated: added an initialistion to show that the code works with true coderefs as well as bareword method names.