in reply to Re: How to tell if a pipe opened for reading has data to be read
in thread How to tell if a pipe opened for reading has data to be read

Doesn't seem to be working. This code prints select()'ed, then blocks for 5 seconds and prints [Piped output] instead of printing nothing yet immediately and exiting.

#!/usr/bin/perl -w
use strict;
use Symbol;

my $sym = gensym;
open($sym, "perl -e 'sleep(5); print qq!Piped output!;' |") or die $!;

my ($rin, $rout);
$rin = '';
vec($rin, fileno $sym, 1) = 1;
my $changed = select($rout = $rin, undef, undef, 0);
print "select()'ed\n";
if ($changed && vec($rout, fileno $sym, 1) == 1) {
    my $buf;
    sysread($sym, $buf, 4096);
    print "[$buf]";
} else {
    print "nothing yet";
}

[download]

Replies are listed 'Best First'.
Re^3: How to tell if a pipe opened for reading has data to be read
by Joost (Canon) on Mar 30, 2007 at 12:11 UTC
    You're suffering from buffering - that program acutally print()s "nothing yet" immediately but you won't see it till the program ends because your output is buffered. try this: 
    #!/usr/bin/perl -w
use strict;
use Symbol;

$|=1; # turn off buffering

my $sym = gensym;
open($sym, "perl -e 'sleep(5); print qq!Piped output!;' |") or die $!;

my ($rin, $rout);
$rin = '';
vec($rin, fileno $sym, 1) = 1;
my $changed = select($rout = $rin, undef, undef, 0);
print "select()'ed: changed=$changed\n";
if ($changed && vec($rout, fileno $sym, 1) == 1) {
        my $buf;
        sysread($sym, $buf, 4096);
        print "[$buf]\n";
} else {
        print "nothing yet\n";
}

    [download]
    "What should it profit a man, if he should win a flame war, yet lose his cool?"
[reply]
[d/l]

In Section Seekers of Perl Wisdom