XML::Twig has options to pretty_print the output, so my $formatted_xml= XML::Twig->parse( pretty_print => 'indented', $xml)->sprint should give yoou what you want.

I find the XML::Writer interface awkward at best. I think it's much easier to build a datastructure and then call either the XML::MyXML::simple_to_xml() or XML::Simple::XMLout() or XML::Rules::ToXML() with the right parameters to emit the XML. You may need to tweak the structure a bit to make sure the XML looks the way it should (eg. to give the module you select a hint what's supposed to be an attribute and what should be a childtag with content). Eg. with XML::Rules the easiest way is to specify the value as a reference to a one element array: ->ToXML( 'root' => { foo => 'hello'}) creates <root foo="hello"/> while ->ToXML( 'root' => { foo => ['hello']}) creates <root><foo>hello</foo></root>. You'll most likely need to do something similar with the other modules.

I've been using XML::Writer for 3 years now and it works very well for my needs; it cannot convert data structures to XML, but it is perfect if you want to compose XML programmatically; its capability of pretty printing is configurable; a good module in my opinion!

use strict;
use warnings;

use IO::String;
use XML::Writer;

my $struct = {
  epoch => time(),
  events => [
    { type => 'move', elements => { left => 1, up => 2 } },
    { type => 'pen', elements => { down => 1, color => 'red' } },
    { type => 'move', elements => { right => 3, up => 1 } },
  ],
};

print to_xml($struct), "\n";

exit;

sub to_xml {
  my $input = shift;
  my $buffer;
  my $io = IO::String->new($buffer);

  my $xml = XML::Writer->new(
    OUTPUT      => $io,
    NEWLINES    => 0,
    DATA_MODE   => 1,
    DATA_INDENT => 2,
  );

  $xml->xmlDecl('UTF-8');
  $xml->startTag(
    'block',
    'time' => $input->{epoch}
  );
  foreach my $event (@{ $input->{events} }) {
    $xml->emptyTag(
      $event->{type},
      %{ $event->{elements} }
    );
  }
  $xml->endTag('block');
  $xml->end();

  return $buffer;
}
[download]

<?xml version="1.0" encoding="UTF-8"?>

<block time="1175447784">
  <move left="1" up="2" />
  <pen color="red" down="1" />
  <move right="3" up="1" />
</block>
[download]

Pod is the simple and efficient way to create docs in perl. Perl comes with programs to convert to other formats.