This seems to work for me.

use strict;

END { print "END\n" };

{
    package SubRef;
    use Scalar::Util qw(weaken refaddr);

    sub DESTROY { my $self = shift; print "DESTROY ".ref($self) ."\n" 
+}

    sub new {
        my $class = shift;
        my $copy;
        my $self = $copy = bless(sub { $copy->ok }, $class);
        weaken $copy;
        return $self;
    }

    sub ok { print "SubRef ok ".refaddr($_[0])."\n" }
}

{
    package ArrayRef;

    @ArrayRef::ISA = qw(SubRef);

    sub new {
        my $class = shift;
        return bless [], $class;
    }
}

{
    package CircularRef;

    @CircularRef::ISA = qw(SubRef);

    sub new {
        my $class = shift;
        my $s = {};
        $s->{self} = $s;
        return bless $s, $class;
    }
}


for (1..2) {
    my $sub  = SubRef->new;
    my $sub2 = SubRef->new;
    my $arr  = ArrayRef->new;
    my $cir  = CircularRef->new;
    $sub->();
    $sub2->();
}

print "After For\n";
[download]

It prints the following:

paul@paul-laptop:~$ perl foo
SubRef ok 135976352
SubRef ok 135976436
DESTROY ArrayRef
DESTROY SubRef
DESTROY SubRef
SubRef ok 135976352
SubRef ok 135976424
DESTROY ArrayRef
DESTROY SubRef
DESTROY SubRef
After For
END
DESTROY CircularRef
DESTROY CircularRef
[download]

I was having issues getting it to work - but then I moved from a one-liner to a program and suddenly the world was fine. I think that the similar action in new would work on your calls also.

Update - Just to double check I used the following lvalue based subref which worked also.

       my $self = $copy = bless(sub :lvalue { $copy->ok; my $n }, $cla
+ss);
[download]