I recently posted a bit of code that does just this, in node Re: How to deal with Huge data. I hope this helps!

...roboticus

The following may get you started:

use strict;
use warnings;

open TEST, '>', 'test1.txt';
print TEST <<DATA;
1
2
3
5
7
9
DATA
close TEST;

open TEST, '>', 'test2.txt';
print TEST <<DATA;
2    
4
5
8
9
DATA
close TEST;

open IN1, '<', 'test1.txt';
open IN2, '<', 'test2.txt';

my $in1Line = <IN1>;
my $in2Line = <IN2>;

while (defined $in1Line or defined $in2Line) {
    if (! defined $in2Line or $in1Line < $in2Line) {
        print "No match from test1.txt: $in1Line";
        $in1Line = <IN1>;
        
    } elsif (! defined $in1Line or $in2Line < $in1Line) {
        print "No match from test2.txt: $in2Line";
        $in2Line = <IN2>;
        
    } else {
        # match
        print "Match: $in1Line";
        $in1Line = <IN1>;
        $in2Line = <IN2>;
    }
}

close IN1;
close IN2;
[download]

Prints:

No match from test1.txt: 1
Match: 2
No match from test1.txt: 3
No match from test2.txt: 4
Match: 5
No match from test1.txt: 7
No match from test2.txt: 8
Match: 9
[download]

The problem you describe has a high degree of commonality with a problem I was presented with in a university Java Data Structures/Sorting Algorithms class. The algorithm you seek to implement is a variant of an "external merge sort".

I'll leave the details for you to implement.

Good luck on your assignment!

#---- find-match.pl------
#!/usr/bin/perl 

use strict;
use warnings;

my %match_files = (
  m1 => 'match',
  m2 => 'nomatch0',
  m3 => 'nomatch1',
);

my %match_fh;
for (keys %match_files) {
  open my $fh, '>', $match_files{$_}
    or die "Can't open $match_files{$_}: $!\n";
  $match_fh{$_} = $fh;
}

while (<>) {
  my $match_result = test_for_match($_); # whatever it is!
  my $fh = $match_fh{$match_result};
  unless ($fh) { # well, just in case
    warn "File $ARGV at line $. returns unexpected match result: $matc
+h_result. Skipped\n"; # or put to another file?
    next;
  }
  print $fh;
  close(ARGV) if eof(ARGV);
}
[download]

$ perl find-match.pl file0 file1 fileN
[download]

The last line in the loop is merely for an aesthetic to allow us identify the correct line number of the currently processed file for throwing warning. You might not need both the last line and the unless clause.

After reading this, you may want to go to at least one of open, perlop, perlvar, and some of perlfaqs. But I think you should go there first though. Simple or super search on the term "read file" will result in a bunch of nodes discussing this issue. Also, you may want to dig a bit on the Q&A part, specially on the files category.

Well, I guess I'm in the mood of something.