To separate the date and time, split on a space.

If you fetch the data with LWP::Simple, then don't set $/, just split on "%%\n". :)

Here's some example code that parses the BeOS Central headlines page, and returns an array of hash refs:

#!/usr/bin/perl -w

use strict;
use LWP::Simple qw(get);
use Data::Dumper qw(Dumper);

#Define the columns to parse out
my @columns = qw(
  headline 
  year month day hour minute second 
  url 
  description
);

#Generate a regex to fetch the column data
my $regex = join '\n', (
  '([^\n]+)',
  '(\d{4})-(\d{2})-(\d{2})\s(\d{2}):(\d{2}):(\d{2})',
  '([^\n]+)',
  '(.*?)\s+', #match everything, except the last bit of whitespace
);

#get the web page
my $text = get('http://www.beoscentral.com/headlines.php');

my @rows;

foreach my $record (split "%%\n", $text) {
  my %row;
  @row{@columns} = ($record =~ /^$regex$/so) or next;
  push @rows, \%row;
}

print Dumper(\@rows);

__END__
[download]

I am sure the regex could be done in a faster/better/elegant way, but the answer eludes me at this time.

Update: Removed the /g modifier from the regex. It was a useless addition to the regex in this case.

#!/usr/bin/perl

undef $/;
my $text=<STDIN>;
my @data=split(/%%\n/,$text);
my ($headline,$datetime,$url,$desc);
foreach (@data) {
    ($headline,$datetime,$url,$desc)=split(/\n/,$_);
    print <<EOF;
Headline: $headline <BR>
Date and Time: $datetime<BR>
URL: $url<BR>
Desc: $desc<BR>
EOF
    next;
    }
[download]

In regards to regular expressions, you might find it helpful to write down exactly how it needs to be split up. You can then turn your individual sentences into fragments of your regular expression.

For more information, check the perlre manpage and the perlfunc entry for unpack. You might also want to look into getting Mastering Regular Expressions.