$item->frobinize(...) == NO_ERR 
    or die($libobj->GetErrorCode);

Since you appear to want to die whenever an error occurs, how about using an assertion?

#! perl -slw
use strict;

sub good{ 0 }
sub bad{ 1 }

sub assert {
    return unless $_[ 0 ];
    die join( ' : ', caller, $_[ 1 ] ) . "\n";
}

assert good(), 'Good() produced an error';
assert bad(),  'Bad() produced an error';

__END__
C:\test>junk5
main : C:\test\junk5.pl : 13 : Bad() produced an error
[download]

If the error string is always available from the library, you might move that into the sub to save some typing, though it would be easier if GetErrorCode() can be called as a class method rather than an instance method.

#!/usr/bin/perl
use strict; use warnings;

package Third::Party::Library::Call; 

use base 'Third::Party::Library';

foreach my $method (qw/bazinate barify/) {
    no strict 'refs';

    my $subref = __PACKAGE__->can($method)
            || die "Unknown method: $method";

    *$method = sub {my $stat = &$subref(@_);
                    return !$stat;
        };
}
[download]

my $libobj =  Third::Party::Library::Call->newObj;
$libobj->bazinate or die $libobj->GetErrorCode;
[download]

I guess you could do

my $libobj = Third::Party::Library->new(...);
my $item = $libobj->NewItem(...);
! $item->frobinize(...) or die($libobj->GetErrorCode);
! $item->blatinate(...) or die($libobj->GetErrorCode);
[download]

but that hardly seems like an improvement.

It contravenes PBP numbers 63-65, but I'm still partial to die $libobj->GetErrorCode unless $item->frobinize( . . . ) == 0.

PBP numbers 63-65

Not having PBP, I don't know what 63-65 might be, but I do know that your way violates perlstyle:

    open FOO, $foo or die "Can't open $foo: $!";
[download]

is better than

    die "Can't open $foo: $!" unless open FOO, $foo;
[download]

because the second way hides the main point of the statement in a modifier. On the other hand

    print "Starting analysis\n" if $verbose;
[download]

is better than

    $verbose and print "Starting analysis\n";
[download]

because the main point isn't whether the user typed -v or not.

A word spoken in Mind will reach its own level, in the objective world, by its own weight

If you're going to break the rules, might as well break them all . . . . :)

My take has always been that using this makes it clear when abnormal termination is the main point (i.e. I expect this condition to be true, so take notice that we can terminate the program at this line).

I understand why PBP and perlstyle recommend against it; however as I said I'm partial to it. Take it or leave it as you may.

my $ret = $item->frobinize(...);
die "Error occured." if $ret;
[download]

The advantage of this method is that you get a handle on $ret, which will usually have some meaning. So you can print it in an error message, or something.

CheckExitCode( $item -> frobinize(...))
  or die($libobj->GetErrorCode);

sub CheckExitCode {
  if ($_[0] == -1) {
    print STDERR "POSIX: failed to execute\n";
        return 0;
  }
  elsif ($_[0] & 127) {
    printf STDERR "POSIX: child died with signal %d, %s coredump\n",
        ($_[0] & 127),
            ($_[0] & 128) ? 'with' : 'without';
        return 0;
  }
  elsif ( !$_[0] ) {
    printf STDERR "POSIX: child exited with value %d\n", $_[0] >> 8;
        return 0;
  }
  1;
}
[download]