$first_num=10.0095;
$last_num=72.0967;
$mem_first="77xptj52";
[download]

and a second file, file2.pl:

use vars qw($first_num $last_num $mem_first);

use strict;

do "file1.pl";

print( "$first_num, $last_num, $mem_first\n" );
[download]

I have tested the above code, which works fine. Now, importing every variable (with use vars) can be quite tiresome. So you'll often find in corporates that use Perl that they often import a single hash with all the data inside, like so (file3.pl):

%everything = (
  first_num => 10.0095,
  last_num => 72.0967,
  mem_first => "77xptj52",
);
[download]

Finally, file file4.pl would contain:

use vars qw( %everything );

use strict;

do "file3.pl";

print( join( ", ",
  $everything{first_num},
  $everything{last_num},
  $everything{mem_first},
  ), "\n" );
[download]

(Also tested, and perl -w file4.pl produces identical results to perl -w file2.pl), hope this helps!

To add to samurai_'s suggestion perhaps you could consider using Data::Dumper to serialise the data.

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

my %cnf = (state_file => 'state.txt');

my $first_num = 10.0095;
my $last_num  = 72.0967;
my $mem_first = q{77xptj52};
my %hash      = (one => 1);
my @array     = qw{one two three};

save_state(
  {
    first_num => $first_num, 
    last_num => $last_num, 
    mem_first => $mem_first,
    hash => \%hash,
    array => \@array,
  }
);

my $state = load_state();

print "first_num: $state->{first_num}\n";
print Dumper $state;

sub save_state{
  my ($state) = @_;
  my $state_file = $cnf{state_file};
  open my $fh, '>', $state_file
    or die $!;
  print $fh Data::Dumper->Dump([$state], [qw(S)]);
  close $fh;
}

sub load_state {  
  our $S;
  my $state_file = $cnf{state_file};
  if (-e $state_file){
    eval {do $state_file};
    die $@ if $@;
  }
  else{
    $S = {time => time};
  }
  return $S;
}
[download]

first_num: 10.0095

$VAR1 = {
          'mem_first' => '77xptj52',
          'hash' => {
                      'one' => 1
                    },
          'array' => [
                       'one',
                       'two',
                       'three'
                     ],
          'last_num' => '72.0967',
          'first_num' => '10.0095'
        };
[download]

There are lots of modules on CPAN which exactly do that.

Have a look at (for example) Config::General or Config::Auto or Config::Framework or Config::Simple (this one has an option to either store the config-values in a hash or import them as variables in your namespace)