I'd be inclined to do this, which pre-codes them in the desired order:

@user_types =(
    [ '037' => 'member' ],
    [ '165' => 'public' ],
    [ '022' => 'staff' ],
    [ '683' => 'babe' ],
    [ '001' => 'old fart' ],
);
[download]

Then you can make a hash for looking up the labels by doing

%lookup = map { @$_ } @user_types;
[download]

However, if this is something that happens a lot in your code, you might consider making your hash order-remembering, e.g. by tieing it to Tie::IxHash:

use Tie::IxHash;

tie my %user_types, 'Tie::IxHash';

%user_types = (
    '037' => 'member',
    '165' => 'public',
    '022' => 'staff',
    '683' => 'babe',
    '001' => 'old fart',
);
[download]

Then accessing the hash via functions like keys, values, and each gives you the data in the desired order.

I'd use an array of hashes.

use List::Util qw( first );
my @user_types
    = ( { name => 'member',
          numb => '037', },
        { name => 'public',
          numb => '165', },
      );
my $selected = first { $_->{name} eq $cgi->param( 'foo' ) } @user_type
+s;
$selected ||= $user_types[0]; # in case nothing is selected
my $selected_numb = $selected->{numb};
[download]

If you don't want to use List::Util::first, you can use grep instead (the list is short). It's easy this way to add any info you want to each element (e.g., a 'key' you put in the HTML form plus a human friendly name that you show to the user). Inside your script you can tie as much data as you want to each element.

037 => 'member'
165 => 'public'
022 => 'staff'
683 => 'babe'
001 => 'old fart'
[download]

Is it a hash or an array of hashes? an array of arrays?

In either case, you have the original order handy, right? I'd use that for the <select>, passing in the user name as label and the index into the original list of tuples as value. If you retrieve the param(), that value serves you as index into the original list.

_($_=" "x(1<<5)."?\n".q·/)Oo.  G°\        /
                              /\_¯/(q    /
----------------------------  \__(m.====·.(_("always off the crowd"))."·
");sub _{s./.($e="'Itrs `mnsgdq Gdbj O`qkdq")=~y/"-y/#-z/;$e.e && print}

When working with items that need to be a specific order, always use an array, avoid using hashes. While you can do a sort of a hash keys (for example) it is easy to forget that you had to have an order for that hash. Also it is easy to overwrite a hash key with a new entry and you may not notice. So use an array.

my @user_types =(
     '037 => member',
     '165 => public',
     '022 => staff',
     '683 => babe',
     '001 => old fart',
);
foreach my $option (@user_types) 
{
   my ($user, $type) = split /\s*=>\s*/, $option;
   make_option($user, $type);
}

<code>
# code => [ 'label', 'order' ]
%user_types =(
     037 => [ 'member', '1' ],
     165 => [ 'public', '2' ],
     022 => [ 'staff', '3' ],
     683 => [ 'babe', '4' ],
     001 => [ 'old fart', '5' ]
);
[download]

@types_sorted = sort { $user_types{$a}[1] <=>  $user_types{$b}[1] } ke
+ys %user_types;

for $i (0 .. $#types_sorted) {
   make options list;
}
[download]

You should be aware that your code, above, creates a hash with keys "37", "165", "22", "683", "1".
Unfortunately, if you want the leading zeroes, you'll need to explicitly quote the keys.

A word spoken in Mind will reach its own level, in the objective world, by its own weight

Actually, it's worse than that. The leading zero causes Perl to interpret it as an octal value, so 037 becomes '31'.

use Data::Dumper;

my %user_types =(
                 037 => [ 'member', '1' ],
                 165 => [ 'public', '2' ],
                 022 => [ 'staff', '3' ],
                 683 => [ 'babe', '4' ],
                 001 => [ 'old fart', '5' ]
              );
print Dumper( \%user_types );
__END__
$VAR1 = {
          '1' => [
                   'old fart',
                   '5'
                 ],
          '18' => [
                    'staff',
                    '3'
                  ],
          '165' => [
                     'public',
                     '2'
                   ],
          '683' => [
                     'babe',
                     '4'
                   ],
          '31' => [
                    'member',
                    '1'
                  ]
        };
[download]