#!/usr/bin/perl -w 
 
use strict; 
 
my %unique; 
while (<DATA>) { 
  chomp; 
  $unique{$_} = ''; 
} 
 
my @array = keys %unique; 
 
 
$, ="\n"; 
print @array; 
 
__DATA__ 
Brentwood 
Brentwood 
Westwood 
Beverly Hills 
Beverly Hills 
Beverly Hills 
Bev Hills Adj. 
Palms 
Mar Vista 
Mar Vista 
Mar Vista 
Mar Vista 
Mar Vista 
Venice 
Santa Monica 
Santa Monica 
LA/Crescent 
LA/Crescent 
Koreatown 
3rd/LaBrea 
3rd/LaBrea 
3rd/LaBrea
[download]

The hash solutions that have already been given have the right idea, but you can use hash slices to make it look a bit simpler.

my %uniq;

@uniq{@orig_list} = @orig_list;

my @unique_list = keys %uniq;
[download]

"Perl makes the fun jobs fun
and the boring jobs bearable" - me

Don't assign values, just assign ().

Or use:

$seen{$_}++ or push @uniq, $_ for @orig;
# or
@uniq = grep !$seen{$_}++, @orig;
[download]



japhy -- Perl and Regex Hacker

And probably even slower, but it avoids the %temp and it's cute:

sort keys %{ { map { $_ => 1 } @orig_list }
[download]


p

That's a needless sort(), unless the original data list was sorted.

japhy -- Perl and Regex Hacker

"look a bit simpler", but run slower if I remember the benchmarks properly.

-- Randal L. Schwartz, Perl hacker

my @data = ( # all that stuff # );

my %hash;

foreach (@data) {
    $hash{$_} = 1;
}

my @new_data = keys %hash;
[download]

or perldoc -q unique if you have a version older than 5.6
snowcrash //////

That'd be a useless use of both cat and uniq.

sort -u file.txt
[download]

-- Randal L. Schwartz, Perl hacker

And to do it all at once as an inline edit:

sort -uo file.txt file.txt
[download]

Update: For those that asked, sort -u file.txt > file.txt
will completely and happily change file.txt into a zero byte file, hence the need for the "o" flag.

ouch ! Didn't know this sort switch !
Thanks.

(Oh my god, I just realized how many useless char I typed during all those years...)