Re: Running external program until N files created

Fork two extra processes (or maybe just one) -- one to run the application, and the other to monitor the directory contents.

if ($proc_pid = fork) {
  # parent
}
elsif (defined $proc_pid) {
  exec $command, @args;
  die "can't exec $command @args: $!";
}
else {
  die "can't fork: $!";
}

if ($count_pid = fork) {
  # parent
}
elsif (defined $count_pid) {
  opendir DIR, $dir_to_be_watched
    or die "can't open $dir_to_be_watched: $!";
  while (1) {
    # UPDATED -- who cares WHAT the files are?
    my $files = -2;  # -2 for . and ..
    $files++ while defined readdir DIR;
    last if $files == $N;
    rewinddir DIR;
  }
  kill -TERM => $proc_pid;
  exit;
}
else {
  die "can't fork: $!";
}

# parent can go on its merry way
[download]

japhy -- Perl and Regex Hacker

Comment on Re: Running external program until N files created Download Code

Replies are listed 'Best First'.
Re: Re: Running external program until N files created by chipmunk (Parson) on Mar 02, 2001 at 02:36 UTC
You may want to make that: `last if $files >= $N;` or even `last if ++$files >= $N while readdir DIR;` Otherwise, the directory could jump from <N to >N files and your script would miss it.	[reply] [d/l] [select]
Re: Re: Re: Running external program until N files created by japhy (Canon) on Mar 02, 2001 at 02:50 UTC
Hmm, good point. Oh, but your second snippet is broken (since Perl doesn't allow multiple post-expression control modifiers). `++$files >= $N and last while defined readdir(DIR);` [download] And keep that defined in there. The files "0" and "" are valid, you know. `japhy` -- Perl and Regex Hacker	[reply] [d/l]