*sigh*. Fish.

use constant NUM_TO_MAKE => 2000;
my @addrs;
my $made = 0;
OUTER:
for my $i ( 1 .. 254 ) {
    for my $j ( 1 .. 254 ) {
        for my $k ( 1 .. 254 ) {
            for my $l ( 1 .. 254 ) {
                push @addrs, "$i.$j.$k.$l";
                last OUTER if ++$made >= NUM_TO_MAKE;
            }
        }
    }
}
[download]

And yes, the 254s are intentional. I don't think you want to be generating probable broadcast addresses; if you do, season to taste.

hmm thx, just to understand ur code OUTER: is to comeout of all the for loops ? i tried something like "last if() " i missed the made also, to keep the how many i made :(

OUTER is a label, as shown in the documentation for last and in perlsyn (see the section "Compound Statements").

I hope you're permitted to use modules that ship with perl. Socket has what you need.

You should use numeric addresses instead of dotted quads for range calculations. That will save you fooling around with nested loops. Socket::inet_aton() and Socket::inet_ntoa() will convert between the two.

Update: Here is a shorty that prints the quads in a range of 2000 above a base address, omitting network addresses.

use Socket qw/inet_aton inet_ntoa/;

my $base = '1.1.1.1';
my $nbase = unpack 'N',inet_aton($base);

my @quads = map { inet_ntoa(pack('N', $_)) }
            grep { $_ % 256 }
            $nbase .. 2000 + $nbase;

{
    local $, = ' ';
    print @quads, $/;
}
[download]

I suggested as much in the CB but the OP persisted in wanting nested loops (hence the fish). Skipping network and/or broadcast addresses is a little trickier when you do it that way, though. Of course the simplest thing is to just install something like Net::Netmask and be done with it (or to just copy the guts into your source if you have to be moduleinstallaphobic for whatever reason; that also was suggested in the CB).