Others may give advice on coding style, I'm off to lunch.

Phil

#! c:\perl\bin

print("Enter filename to open (text only):\n\n");
[download]

No

use strict;
use warnings;
[download]

Too bad!

$in=<STDIN>;
chomp $in;
    if ($in !~ /\.txt$/i)
        {
            $in.=".txt";
        }
[download]

chomp(my $in=<STDIN>);
$in .= '.txt' unless $in =~ /\.txt$/i;
[download]

open ($in, "$in") or die("$in could not be opened:$!\n");
[download]

Too bad: not only it features useless quoting of variables, but it's also wrong in that for lexical filehandles to work, the variable must be undefined.

open my $infh, '<', $in or die "$in could not be opened:$!\n";
[download]

        s/\band\b/$word/ig;
                
                while (/\band\b/ig)
                    {
                    ++$count;
                    }
[download]

After you've substituted all occurrances of 'and' with $word, there won't be many remaining unless $word =~ /\band\b/i. Count around the substitution, instead.

while (<$in>)
        {            
        s/\band\b/$word/ig; # <- Here you make all the substitutions
                
                while (/\band\b/ig) # <-... and here nothing happens!
                    {
                    ++$count;
                    }
                    
        print($out "$_\n");
}
[download]

s/// will return the number of occurrences, so...

while (<$in>)
        {            
        $code = s/\band\b/$word/ig; # <- Here you make all the substit
+utions
## UPDATE:
## $code += s/\band\b/$word/ig; # <- Here you make all
## Sorry for the mistake (thanks blazar!)
                    
        print($out "$_\n");
}
[download]

should works

citromatik

Thanks for your help. Tried this, and $code appears to be empty. I've declared it outside the While loop, but it prints out as null. Should this contain the total substitutions?

Thanks for your help. Tried this, and $code appears to be empty. I've declared it outside the While loop, but it prints out as null. Should this contain the total substitutions?

Well, for one thing I wouldn't regard $code as a particularly good variable name. Then, if you want the total number of substitutions, you must accumulate them:

$count += s/\band\b/$word/ig;
[download]

Hi scarymonster,

Perl is a very flexible and powerful language, even powerful enough to shoot away your own foot, and perl won't complain. But there exists a perl-builtin pragma with name use warnings; which tries to warn you if you write code that might be problematic and to warn you from some errors that may be difficult to be found. If you dont understand what such a warning means, also use diagonstics; which will try to explain why this might be dangerous.

Another very big help is use strict; which may save you from a lot of other - difficult to find - errors. Why you should use strict is a very good node to start with, and Use strict and warnings and 101 reasons to use strict and Why We Use Strict and Use strict warnings and diagnostics.

So it's a good idea to start every program with the following lines:

#! /usr/bin/perl
use warnings;
use strict;
use diagnostics;
[download]

Here some stuff for security:

You don't control if the filenames given are really filenames, and not commands that will be executed. Try the following code which will try to open notepad under windows:

use warnings;
use strict;
my $filename = 'notepad |';
open( my $FH, $filename ) or die "Can't open '$filename': $!\n";
[download]

You can easily avoid this if you use the open with three parameters:

use warnings;
use strict;
my $filename = 'notepad |';
open( my $FH, "<", $filename ) or die $!;
[download]

And if you want to open an existing file for reading, it might also be a good idea to check if it is really existing before opening it:

my $filename = 'notepad |';
unless( -f $filename ) {
    die "Error: file '$filename' is not existing\n";
} # unless
[download]

e.g

#! /usr/bin/perl
use warnings;
use strict;
use diagnostics;

print "Enter filename to open (text only):\n\n";
my $infile = <STDIN>;
chomp $infile;

unless( -f $infile ) {
    die "Error: file '$infile' is not existing\n";
}
open( my $INFILE, '<', $infile )
    or die "Error: can't open '$infile' for reading: $!\n";

print "Enter filename to SAVE text file as:\n\n";
my $outfile = <STDIN>;
chomp $outfile;

open( my $OUTFILE, '>', $outfile )
    or die "Error: can't open '$outfile' for reading: $!\n";

print qq~Enter string to replace "and" with\n\n~;
my $word = <STDIN>; chomp $word;

print "\n" x 3;

my $count = 0;

while( <$INFILE> ) {
    $count += s/
                \band\b
               /$word/gix;
    print $OUTFILE $_;
} # while

close $INFILE
    or die "Error: can't close '$infile' for reading: $!\n";
close $OUTFILE
    or die "Error: can't close '$outfile' for writing: $!\n";

print qq~There were $count instances of "and" in '$infile'\n";
[download]