Sure you can do the same thing in perl. See Sub::Versive for instance.

Perl 6 has a new .wrap method just for this sort of thing.

In Perl 5, this technique comes to my (sleepy) mind:

use strict;
use warnings;

sub greet {
    my ($name) = @_;

    print "Hi, $name!\n"
      or return 'Shame :(';

    return 'Glory !';
}

sub wrap_the_sub {
    my ($sub_name) = @_;
    my $sub_ref = \&{$sub_name};
    my $wrapping_sub = sub {
        my @args = @_;
        print "Entering '$sub_name'\n";
        my $rc = $sub_ref->(@args);
        print "Exiting '$sub_name'\n";
        # Really need some wantarray() trick there...
        return $rc;
    };
    no strict 'refs';
    no warnings 'redefine';
    *{$sub_name} = $wrapping_sub;
}

wrap_the_sub('greet');

my $result = greet('Util');
print "Result was: '$result'\n";
[download]

Entering 'greet'
Hi, Util!
Exiting 'greet'
Result was: 'Glory !'
[download]

sub wrap
{
    my ($name, $outer) = @_;
    my $inner = \&$name;
    *{$name} = sub {
        $outer->($inner, @_);
    };
}

sub foo
{
    print "foo\n";
}

wrap 'foo', sub {
    my $foo = shift;
    print "called foo with (@_)\n"; $foo->(@_);
};

foo('args');

wrap 'foo', sub {
    my $foo = shift;
    print "called AGAIN foo with (@_)\n"; $foo->(@_);
};

foo('more args');
__END__
called foo with (args)
foo
called AGAIN foo with (more args)
called foo with (more args)
foo
[download]