The problem is that use calls are evaluated at BEGIN time, while your lexical variable declarations are called after that. Although use lib LIST does not try to import a module, it's still a compile-time pragma, and to my knowledge, those are still evaluated at BEGIN time.

So, I recommend trying this:

my $mod_path; # or @mod_path, if you're so inclined.
BEGIN { $mod_path = '/home/ripenapp/perl_mods'; }
use lib $mod_path;
use Email::Valid;
[download]

What this does is ensure that a value is assigned in $mod_path before use lib $mod_path is called -- as use calls are implicitly wrapped in BEGIN blocks (see use and lib) and BEGIN blocks are executed sequentially in the order of definition (see perlmod).

By the way, you do use strict, right? use lib $mod_path ought to complain in your example code, as the variable hasn't been assigned a value before use lib is called...

This is just FYI. If you want to use directory as library on unix, where your script is being called. for e.g.

>perl /home/abcd/script.pl
[download]

then you can also use following code

BEGIN {
       if ($0 =~ m/^(.*?)[\/\\]([^\/\\]+)$/) {
               $runtimedir = $1;
               $program = $2;
       }
}

use strict;
use lib $main::runtimedir;
[download]

It's because the use statements are "compiled" before the rest of the code. Why do you want to do it that way?

BEGIN {
my $mod_path = '/home/tanger/www/mods';
use lib $mod_path;
};
use Email::Valid;
[download]

This was covered recently. Your solution doesn't work because the assignment is still executed after the use. The use statement finishes compiling before the BEGIN statement, so it's executed first. A fix:

my $mod_path;
BEGIN { $mod_path = '/home/tanger/www/mods'; }
use lib $mod_path;
use Email::Valid;
[download]

Follow the above link for alternative solutions.

This is because use lib $mod_path is evaluated during compile time (it's equivalent to BEGIN { require lib; lib->import($mod_path) ; } - but the assignement to $mod_path is done during runtime - in effect you are calling lib->import with an empty list as argument

I modified my lib.pm to produce a little message every time import is called:

my @mod_path = '/home/ripenapp/perl_mods';
use lib @mod_path;
use Email::Valid;
__END__
tomte@librics-tomte ~/scratch/test $ perl test.pl
Importing:
[download]

Your first version:

use lib '/home/tanger/www/mods';
use Email::Valid;
__END__
tomte@librics-tomte ~/scratch/test $ perl test.pl
Importing: /home/tanger/www/mods
[download]

If you want to conditionally load modules at runtime, you want require:

sub validate_fields {
    ...
    if($q->param(mail)) {
        my $mod =  '/home/tanger/www/mods';
        unshift @INC, $mod
            unless $INC[0] eq $mod;
        require Email::Valid;      # to include the code
        import Email::Valid;       # to import symbols into your names
+pace
        ...
    }
    ...
}
[download]

Read perlmod - I've done that again yesterday. It is good to re-read manual pages, since there are always things in them which escape your attention in the first place, but get important when your knowledge of perl deepens. Read the docs, and often! :-)

--shmem

_($_=" "x(1<<5)."?\n".q·/)Oo.  G°\        /
                              /\_¯/(q    /
----------------------------  \__(m.====·.(_("always off the crowd"))."·
");sub _{s./.($e="'Itrs `mnsgdq Gdbj O`qkdq")=~y/"-y/#-z/;$e.e && print}

Well, your use statements will get executed at compile-time whether the condition is true or not. To conditionally load a module at runtime, you can do this:

if ( $want_to_check_email ) { 
    unshift @INC, $mod_path;
    require Email::Valid;
    Email::Valid->import;
}
[download]