You want a hash of arrays. That simplifies the logic and puts the data all in one place.

my %data = (
    foo1 => [
        '1 - 201 - 229',
        '2 - 201 - 229',
        '3 - 201 - 229',
    ],

    foo2 => [
        '1 - 201 - 218',
        '2 - 201 - 218',
        '3 - 201 - 218',
        '4 - 201 - 218',
        '5 - 201 - 218',
        '6 - 201 - 218',
        '7 - 201 - 218',
   ],

# . . . 
);
[download]

my @act_bsites = @{$data{$dataset}};
[download]

Update: I don't understand how hardcoding the data in an extended if-else construct improves anything with respect to hard-won data. Here's a version with a seperate data file:

# file: /path/to/foosites
{
    foo1 => [
        '1 - 201 - 229',
        '2 - 201 - 229',
        '3 - 201 - 229',
    ],

    foo2 => [
        '1 - 201 - 218',
        '2 - 201 - 218',
        '3 - 201 - 218',
        '4 - 201 - 218',
        '5 - 201 - 218',
        '6 - 201 - 218',
        '7 - 201 - 218',
   ],

# . . . 
};
[download]

my @act_bsites = @{(do '/path/to/foosites')->{$dataset}};
[download]

If you've got 150 if/elsif conditions I'd suggest taking a step back and rethinking the design. A dispatch table might be a more elegant solution.

Secondly, I'm not sure how much your data in @act_bsites varies, but from the example you posted it looks like you could generate this on the fly with a few parameters. For example:

use strict;
use warnings;

use Data::Dumper;

my %foodata = ( 'foo1' => { thirdpart => 229, size => 3 },
                'foo2' => { thirdpart => 218, size => 7 } );

foreach my $foo qw( foo1 foo2 )
{
    my @act_bsites = map
                     {
                        join( ' - ', $_, 201, $foodata{$foo}{thirdpart
+} )
                     } 1 .. $foodata{$foo}{size};

    print Dumper( \@act_bsites );
}
[download]

Finally, to actually answer your question, yes. You can put the data and/or the conditions into a separate file. See use, do, and eval (then there's the OO approach...).

I apologize for being a bit on the vague side, but I'd rather understand the problem a little better before jumping in and recommending a complete solution.

Update following the update to the OP:
A database comes to mind, but that might be overkill. If so, I'd suggest putting the data into 150 separate files. Use a simple lookup mechanism (e.g., a hash) to determine the appropriate path/filename for a given input (e.g., 'foo1'), then use a single routine (which takes the path/filename as a parameter) to read in the data. If your data sets are small, you could put them all into one file, as GrandFather suggested.

Either toss the data into a module or into an external file and use something like:

use warnings;
use strict;

my $dataset = 'foo1';
my %site_data;
my $site;

while (<DATA>) {
    chomp;
    next unless length;
    
    if (/^(\w+):$/) {
        $site = $1;
        next;
    }
    
    push @{$site_data{$site}}, $_;
}

die "No site data for $dataset" unless exists $site_data{$dataset};

my @act_bsites = @{$site_data{$dataset}};

print join "\n", @act_bsites;

__DATA__
foo1:
1 - 201 - 229
2 - 201 - 229
3 - 201 - 229
foo2:
1 - 201 - 218
2 - 201 - 218
3 - 201 - 218
4 - 201 - 218
5 - 201 - 218
6 - 201 - 218
7 - 201 - 218
[download]

Prints:

1 - 201 - 229
2 - 201 - 229
3 - 201 - 229
[download]

to access it.

In answer to the Update:

so chuck the whole current file into the __DATA__ section and:

local $/ = 'if (';

while (<DATA>) {
    chomp;
    next if ! length;
    next unless /eq '(\w+)'/;
    
    my $site = $1;
    push @{$site_data{$site}}, /'(\d+[^']+)'/gm;
}
[download]

to parse it.

Why do something on your own if CPAN can do the same for you?

Just store the Hash of Arrays in a serialized format (such as YAML, JSON, XML or even use Data::Dumper to write to a perl file) and you don't have to worry about parsing and writing theses lines by yourself

---

Perl 6 in German

Hi,
That's interesting. Can you give example how this can be done with one of those modules?


---
neversaint and everlastingly indebted.......