Re: array splitting

Deal with the problem a little at a time. First bit is loop over the elements (with strictures, declarations and initialisation thrown in):

use warnings;
use strict;

my @times = (5, 10, 20, 25, 30, 40, 45, 50, 55, 65, 75, 80, 90);
my @times1;
my @times2;

for my $elmt (@times) {
[download]

Then deal with the first case (and the special case for the first element):

    if (! @times1 || $elmt - $times1[-1] >= 10) {
        push @times1, $elmt;
        next;
    }
[download]

Then deal with the second case (and again the special case for the first special element):

    if (! @times2 || $elmt - $times2[-1] >= 10) {
        push @times2, $elmt;
        next;
    }
[download]

Then deal with the exception (and close the loop body):

    push @times1, $elmt;
}
[download]

Finally print the result:

print "Times1: @times1\n";
print "Times2: @times2\n";
[download]

Prints:

Times1: 5 20 30 40 50 65 75 90
Times2: 10 25 45 55 80
[download]

DWIM is Perl's answer to Gödel

Comment on Re: array splitting Select or Download Code

Replies are listed 'Best First'.
Re^2: array splitting by CColin (Scribe) on Jun 05, 2007 at 12:26 UTC
I note the code I posted actually didn't even work for the first list. I note this code does work and there's a few things in this that I don't know well, so good for learning, thank you. `if (! @times)` presumably means if there is nothing in the array? This is a general confusion I have with perl, about what tests for a value being present in a variable and what "undef" means. I assume the exclamation mark I can always use to determine if values are (not) present in a variable from now on? Colin	[reply] [d/l]
Re^3: array splitting by blazar (Canon) on Jun 05, 2007 at 18:09 UTC
if (! @times) presumably means if there is nothing in the array? Yes. Alternatively you could use `unless (@times) { # ...` [download] which may be clearer to understand naively, based on the rationale that a full thingy is true and an empty one is false. This is a general confusion I have with perl, about what tests for a value being present in a variable and what "undef" means. undef is a builtin function which can take a variable and give it a special value which is also its own return value. The latter is thus in turn also called `undef`: in fact the function is often used with no argument in which case it simply returns it. undef is a particular false value, precisely the one that also have variables which have not been initialized at all. I assume the exclamation mark I can always use to determine if values are (not) present in a variable from now on? The exclamation mark is simply a logical "not" that turns a true value into a false one and vice versa.	[reply] [d/l] [select]