In real life, I would normally use a splice like Errto and jdporter.

Before *any* solution, I would put:

die if @ref / 3;
[download]

Most elegant, non-destructive Perl5 solution I could think of:

my %out = map  { $ref[$_] => [ @ref[$_+1..$_+2] ] }
          grep { not $_ % 3 }
          0 .. $#ref;
[download]

Even better, but requires Perl6:

for @ref -> $key, $val1, $val2 {
    %out{$key} = [ $val1, $val2 ];
}
[download]

Update: Better yet, this also works in Perl6:

my %out = map -> $k, $v, $w {
    $k => [ $v, $w ];
}, @ref;
[download]

Ah-HAH! :)

(I *really* liked that Perl6 solution, BTW; I see that I'm going to have to get off my lazy butt and dig into it.)

All of that - particularly Util's solution - has finally caused a reticent neuron to fire. Originally, I thought of this:

$out{shift @ref} = [splice @ref,0,2] while @ref;
[download]

...but there's a precedence problem with that, so that %out ends up containing stuff like

2 => [ 0, 1 ],
5 => [ 3, 4 ]
etc.
[download]

so my final cut at it ends up being this:

die if @ref % 3;
$out{$a} = [splice @ref,0,2] while $a = shift @ref;
[download]

I'm definitely up for seeing more solutions, though. You folks come up with some very pretty thought patterns. :)

Thank you all!

I can't resist offering a shorter Perl 6-solution:

my %out = map {$^k => [$^v, $^w]}, @ref;

The ^ secondary sigil ("twigil") is a self declaring formal paramter, all of the variables starting with $^ will be filled in the block in lexicographic order.

---

Perl 6 in German

die if @ref / 3;

I really like the idea of an assertion (especially during debugging), but I'd probably write it this way:

die 'Assertion failed: @ref not divisible by 3'
    if scalar @ref % 3;
[download]

If I'm not mistaken, yours dies every time @ref has any elements.

while (@array) {
   my ($key, @vals) = splice @array, 0, 3;
   $hash{$key} = [ @vals ];
}
[download]

my @destructible = @$ref;

while ( @destructible )
{
    my( $key, @val ) = splice @destructible, 0, 3;
    $out{ $key } = \@val;
}
[download]

my %hoa = map { $array[$_], [ @array[ $_+1 .. $_+2 ] ] } 
    grep { !($_ % 3) } 0 .. $#array;
[download]

Elegant? Fun!

my @ref = map{ ("key$_", "value1_$_", "value2_$_") } 0 .. 9;;

my $i=0; $h{shift @$_}=$_ while $i < @ref and $_=[@ref[$i++,$i++,$i++]
+];;

print "$_ => @{$h{ $_ }}" for sort keys %h;;
key0 => value1_0 value2_0
key1 => value1_1 value2_1
key2 => value1_2 value2_2
key3 => value1_3 value2_3
key4 => value1_4 value2_4
key5 => value1_5 value2_5
key6 => value1_6 value2_6
key7 => value1_7 value2_7
key8 => value1_8 value2_8
key9 => value1_9 value2_9
[download]

I'm afraid that doesn't work for me, ysth. 'selectall' rather than 'selectcol' is the deal-killer here (I don't see the need for fetching the entire content of that table, extracting the columns, and then doing all this processing.)

This gets me exactly the info I need - although the structure is a little different from what I want:

my @ref = @{
    $dbh->selectcol_arrayref(
        "select date, label, subject from travel
         where date>= curdate()-5 order by date",
         {Columns=>[1,2,3]}
    )
};
[download]

I do indeed appreciate your attempt to approach it from a broader viewpoint - I try not to lose track of the fact that stepping back can be as important as focusing down when trying to solve a problem. [Grin] Hell, my wife is Japanese-American. She'd beat my butt if I was ever so silly as to lose track of context.

I'm not understanding you at all. There's either something I'm missing or something you are. selectcol_arrayref and selectall_hashref will both read all the available rows. Yes, selectcol_arrayref by default throws away all but the first column, but in your invokation, you are telling it to keep all three columns.

Option 1:

while (@ref) {
  my $k = shift(@ref);
  $out{$k} = [ shift(@ref), shift(@ref) ];
}
[download]

while (@ref) {
  $out{$_} = [ shift(@ref), shift(@ref) ] for shift(@ref);
}
[download]

Option 2: Change your SQL to something like SELECT key, value1, key, value2, then do:

push @{ $out{shift(@ref)} }, shift(@ref) while (@ref);
[download]