The seperator is matched, so it must be seperating two things. One of them must therefore be "". It allows the following three cases to be distinguished: a=b vs a= vs a.

for ('a=b', 'a=', 'a') {
   my ($p1, $p2) = split(/=/, $_, 2);
   print(
      "$_\t",
      (
         !defined($p2) ? 'undef' :
         !length($p2)  ? '""' :
         qq{"$p2"},
      ),
      "\n"
   );
}
[download]

a=b     "b"
a=      ""
a       undef
[download]

Ok, that makes sense ie being able to tell if it matched the separator at all

If you hadn't specified the limit, you would have got what you expected:

Splits the string EXPR into a list of strings and returns that list. By default, empty leading fields are preserved, and empty trailing ones are deleted. (If all fields are empty, they are considered to be trailing.)

...

If LIMIT is unspecified or zero, trailing null fields are stripped (which potential users of "pop" would do well to remember).

#!/usr/bin/perl -w
use strict;
sub pr {
    print "'$_[0]' (no limit) => [".join(",",map { defined $_ ? "'$_'"
+ : 'undef' } split /=/,$_[0])."]\n" ;
    print "'$_[0]' (limit 1) => [".join(",",map { defined $_ ? "'$_'" 
+: 'undef' } split /=/,$_[0],1)."]\n" ;
    print "'$_[0]' (limit 2) => [".join(",",map { defined $_ ? "'$_'" 
+: 'undef' } split /=/,$_[0],2)."]\n" ;
}

pr('');
pr('a');
pr('=');
pr('a=');
pr('a=b');
[download]

'' (no limit) => []
'' (limit 1) => []
'' (limit 2) => []
'a' (no limit) => ['a']
'a' (limit 1) => ['a']
'a' (limit 2) => ['a']
'=' (no limit) => []
'=' (limit 1) => ['=']
'=' (limit 2) => ['','']
'a=' (no limit) => ['a']
'a=' (limit 1) => ['a=']
'a=' (limit 2) => ['a','']
'a=b' (no limit) => ['a','b']
'a=b' (limit 1) => ['a=b']
'a=b' (limit 2) => ['a','b']
[download]

I haven't tried your more exotic version, but if you remove the limit cnt from my simple code, you still get the empty string...
Actually, that's the first thing I tried after it didn't 'work', given that my data only has var=val (if there is a val to get)

Hmm.. You mean like this:

#!perl -w
use strict;
$_ = 'event_handler=';
my ($var1, $var2) = split( /=/);
if( !defined($var2) ) {
    print "undefined\n";
}
else {
    print "'$var1' '$var2'\n";
}
[download]

output:

'event_handler' ''
[download]

that does seem to be inconsistent with the docs. And what's even more confusing is that:

#!perl -w
use strict;
$_ = 'event_handler=';
my @arr = split(/=/);
my ($var1, $var2) = @arr;
if( !defined($var2) ) {
    print "undefined\n";
}
else {
    print "'$var1' '$var2'\n";
}
[download]

output:

undefined
[download]

Confirms the docs.

updated: added output for perl 5.8.8 / linux

"What should it profit a man, if he should win a flame war, yet lose his cool?"

You can achieve what (I presume) you want by ensuring there is at least one character following the match:

( $var1, $var2 ) = split( /\s*=\s*(?=.)/, $t_arr[0] );
[download]

Note however that if you are hand rolling an .ini file parser, that there area a plethora of modules to do the job on CPAN. See Config::Ini and Config::IniFiles for example.

As it happens, the empty string is easier (simpler code), because it's going to be inserted into an Ingres NOT NULL column and I don't have to check/cvt the value from 'undef'.
No, this isn't a .ini file parser btw.