Hello,
If the only thing you want to do is to weed out the blank lines, a one-liner could do the trick:

*nix version:
 perl -ni.bak -e 'print unless /^\s*$/' myFile
Win32:
 perl -ni.bak -e "print unless /^\s*$/"  myFile
[download]

In the future, you may want to check the search functionnality of perlmonks, I found all these relevant nodes about your question:

• Cannot seem to remove empty/blank lines
• How do I remove blank lines from text files?
• How do I strip blank space from the beginning/end of a string?
• and probably a bunch of others...

Cheers,
Briac

Update:
For this node to be really useful here's why your snippet doesn't work:

Your regex did indeed match an empty line, but the newline "\n" character is not matched by the regex. So your program happily replace an empty string (with a non-matched newline) with another empty string (with the newline it has not matched). Should you have chomp'd the line, everything would have run smoothly (but you'd then have to add the newline at the end of the lines you want to print)

#!/usr/bin/perl -w 

use strict;


my $line;
my $element;
my @list;


while ($line = <DATA>){
  chomp $line;
  unless ($line =~ /^\s*$/) {
    push(@list, $line);
  }
}
foreach $element(@list){
  print "my remaining lines are: $element\n";
}

__DATA__

1    1    Foo    Bar    Baz
  
2    2    Foo    Bar    Baz

__END__
[download]

$entire_file =~ s/^\n$//mg;
[download]

$entire_file =~ s/^\n$//mg;

That should leave $entire_file with only nonblank lines

This is assuming that blank lines are TRUELY blank (no spaces). This is more general:

perl -pi -e 's!^\s+?$!!' file.txt

or

s!^(\n|\s+)$!!g
[download]

Cheers,
KM

Still far too much typing:

perl -ni -e 'print if /\S/' file.txt
[download]

-- Randal L. Schwartz, Perl hacker

The first one-liner will not have the intended effect:     perl -pi -e 's,^\s+?$,,' file.txt only works on lines that consist of a newline. For lines that contain whitespace followed by a newline, the newline is not removed because of the non-greedy quantifier. (Although you could run the one-liner twice... ;)

In the second one-liner:     perl -pi -e 's,^(\n|\s+)$,,g' file.txt the alternation and the /g are unnecessary.

This is sufficient: perl -pi -e 's,^\s+$,,' file.txt

unless (<FILE> =~ /([a-z]|[A-Z]|[0-9]/) {
#delete line
}
[download]

#!/usr/local/bin/perl

open (FILE, "/home/robert/Print/foo") || die "Cant open /home/robert/f
+oo\n\n";

# Create a file array of lines
while ($line = <FILE>)
{
    push (@array, $line);
}

# Then control the output
foreach $index (@array)
{
    # if the line is completely blank dont print it.
    if ($index !~ /^\s*\n\s*$/)
    {
        print "$index";
    }
}
[download]

# Create a file array of lines
while ($line = <FILE>){
    push (@array, $line);
}
[download]

ew.... just do:

my @array = <FILE>;
[download]

# Then control the output
foreach $index (@array){
    # if the line is completely blank dont print it.
    if ($index !~ /^\s*\n\s*$/)    {
        print "$index";
    }
}
[download]

ewwwww... use something more like:

for (@array) {
    print unless /^(\n|\s+)$/;
}
[download]

Even better, do it from the command line (see another node in this same thread)

Cheers,
KM