something like this would work:

use strict;
use XML::Twig;

my @nodes = qw(title toc bar);

my %found;
my $t = XML::Twig->new(
    twig_handlers => { map { $_ => sub { $found{$_->name()}++ }; } @no
+des }
);

$t->parsefile(shift()); # read file specified at command line

$t->flush; # update: you may need this

for (@nodes) {
    die "$_ not found" unless $found{$_};
}
[download]

Joost, fantastic! Worked like a champ! Now I need to spend a few minutes to understand what the following line is doing.

twig_handlers => { map { $_ => sub { $found{$_->name()}++ }; } @nodes }

# specify twig_handlers (see the XML::Twig documentation)
twig_handlers => 
   { # create a new hash-ref
       map { # transform a list into a new list 
             # create a name / subroutine pair
             $_ => sub {
                # when the subroutine is called
                # get the element name from $_->name()
                # and increase it's count entry in %found
                #
                # note: $_ is set by XML::Twig when the sub is called
                $found{$_->name()}++ 
             }; 
       } @nodes # for each element in @nodes
   }
[download]

See also map.

"What should it profit a man, if he should win a flame war, yet lose his cool?"