The subject line of your question contains the words "key values", that could have given you a hint that you can solve this problem using a hash :-).

Normally I recommend using Text::CSV_XS on CSV files, but this example data looks simple enough to handle without an extra module (reconsider using the module if your real datafiles should contain things like quoted data or escaped commas):

#!/usr/bin/perl

use strict;
use warnings;

my %result;

for my $file ("File_A","File_B","File_C") {

    open (my $fh,"<",$file) or die "Can't open file $file: $!";
    <$fh>; # skip header line

    while (my $line = <$fh>) {
        my ($server,$cpua) = (split(",",$line))[0,1];
        push @{$result{$server}},$cpua;
    }

    close $fh or die "Can't close file $file: $!";
}

open (my $nfh,">","Result_File") or die "Can't open result file: $!";

for my $server (sort keys %result) {
    print $nfh $server.",".join(",",@{$result{$server}})."\n";
}
close $nfh or die "Can't close result file: $!";
[download]

This assumes that you want the result file to contain the servers listed in alphabetical order. If you want a different ordering, simply construct an array holding the server names in the order you want them and use that for the final loop. For example

my @order = qw(wsompapgtw05 wsomddvfxa01 wsomdavpra03 WSOMQAVPRA05);

for my $server (@order) {
...
[download]

tirwhan, thanks for your help. Your solution assumes that the 3 input files have the server names in the same order in each of the 3 files. This is not always the case. How do you get the for and while loops to match the keys (i.e., server name) regardless of where they are in the 3 input files?

Your solution assumes that the 3 input files have the server names in the same order in each of the 3 files

Umm, no it doesn't. The cpu value get associated with the server name, regardless on which line they appear. Output order is also regardless of the order the servers are in in the input files. Try it out and you'll see (this is a hash, not an array!).


All dogma is stupid.

$ join -t, file1.txt file2.txt | join -t, - file3.txt | cut -f 1,2,6,1
+0 -d,
WSOMQAVPRA05,93.75,34.78,93.13
wsomdavpra03,90.39,69.04,68.85
wsomddvfxa01,39.22,92.44,46.97
wsompapgtw05,49.6,48.77,30.66
[download]

Note that join is dependent on the sort field being in the same order in both input files, so you'll need to sort into temp files if this isn't known to be the case. If you are making temp files, though, you can do a sort <filename> | cut -f1,2 -d, > <tempfile> and eliminate the need for the final cut after joining the files, which makes it a bit easier to generalize to different numbers of files.