I think maybe you want this:

while (<FILE>){ 
     my ($src,$sport) = (split /;/)[9,12];
     $hash{$src}{$sport}++;  
}
[download]

Then you can say something like...

foreach my $src ( keys %hash ) {
    foreach my $sport ( keys %{$hash{$src}} ) {
        printf "%s appears with %s %d times\n",
               $src, $sport, $hash{$src}{$sport};
    }
}
[download]

Or just use something like Data::Dumper or YAML to spew out the whole structure.

I'd simplify it a bit further:

my %count;
while (<FILE>) {
    my( $src, $sport ) = (split /;/)[9,12];
    $count{$src,$sport}++;  # magic $;
}

for my $pair ( sort keys %count ) {
    print "($pair) occurred on a line together $count{$pair} times\n";
    # if you need the two parts:
    # my( $src, $sport ) = split $;, $pair;
}
[download]

In fact, I'd extend it to any number of fields:

my @fields = ( 9, 12 );

my %count;
while (<FILE>) {
    chomp;
    $count{ (split /;/)[@fields] }++;
}

for ( sort keys %count ) {
    print "($_) occurred on a line together $count{$_} times\n";
    # if you need the parts:
    # my @vec = split $;;
}
[download]

Cool, this is what I went with and it does exactly what I want, thanks!

P.S. I looked at your home node and saw "Other monks I've met in person:" line and when I first read it, I thought it said "Other monks I've met in prison!!"

P.P.S. Thanks to the other monks for their responses as well.


Thanks,
Dru

Perl, the Leatherman of Programming languages. - qazwart

my %count;
my $total;
while (<FILE>) {
  chomp;
  my($src, $sport) = (split /;/)[9,12];
  my $number_of_sport_shows_on_this_line = () = /$sport/gi;
  $count{$.} = $number_of_sport_shows_on_this_line;
  $total += $number_of_sport_shows_on_this_line;
}

# iterate %count to see how many the pattern shows up on each line
# $total is the total number the pattern shows up in the file
[download]

my(%count, $total);
while (<FILE>) {
  chomp;
  my @fields = split /;/;
  my %seen;
  $seen{$_}++ for @fields;
  my $target = $fields[12];
  $count{$.} = $seen{$target};
  $total += $seen{$target};
}
[download]

Update: (15-07-2007) I misread the title, I missed the "appear together" part, and I second kyle's reply.

my $count = 0;
while (<FILE>){ 
    $count++ if /\Q$src/ && /\Q$sport/;
}
print "Both found a total of $count times\n";
[download]

use strict;
use warnings;

my @strings = qw{
   0;1;2;3;4;5;6;7;8;9;10;11;12;13
   0;1;2;3;4;5;6;7;8;9;10;11;9;8
   0;1;2;3;4;5;6;7;8;9;10;11;99
   0;1;2;3;4;5;6;7;8;9;10;11;9
   0;1;2;3;4;5;6;7;8;;10;11;;13
   0;1;2;3;4;5;6;7;8;;10;11;12;13
   };

my $rxByPosn = qr
   {(?x)
       \A            # Start of string
       (?:[^;]*;){9} # Nine fields/delimiters
       ([^;]*)       # Capture 10th field, which
                     #   could be blank
       ;             # Delimiter
       (?:[^;]*;){2} # Two more fields/delimiters
       \1            # 13th field must match 10th
       (?:;|\z)      # Delimiter or end of string
   };

foreach my $string ( @strings )
{
    print
       qq{String - $string\n},
       $string =~ $rxByPosn
       ? qq{     Col. 10 matches col. 13\n} 
       : qq{     Cols 10 and 13 differ\n} ;
}
[download]

The output.

String - 0;1;2;3;4;5;6;7;8;9;10;11;12;13
     Cols 10 and 13 differ
String - 0;1;2;3;4;5;6;7;8;9;10;11;9;8
     Col. 10 matches col. 13
String - 0;1;2;3;4;5;6;7;8;9;10;11;99
     Cols 10 and 13 differ
String - 0;1;2;3;4;5;6;7;8;9;10;11;9
     Col. 10 matches col. 13
String - 0;1;2;3;4;5;6;7;8;;10;11;;13
     Col. 10 matches col. 13
String - 0;1;2;3;4;5;6;7;8;;10;11;12;13
     Cols 10 and 13 differ
[download]

I hope this is of use.

Cheers,

JohnGG